blob: e0c095bfbe9fde5cd5a211b72078b8b416a86693 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
CMAKE_MAKEFILE_GENERATOR="emake"
FORTRAN_STANDARD=2003
inherit cmake fortran-2
DESCRIPTION="A GTK+ binding to build Graphical User Interfaces in Fortran"
HOMEPAGE="https://github.com/vmagnin/gtk-fortran"
SRC_URI="https://github.com/vmagnin/${PN}/archive/v20.04.gtk${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${PN}-20.04.gtk${PV}"
LICENSE="GPL-3"
SLOT="3"
KEYWORDS="~amd64 ~x86"
IUSE="examples high-level plplot static-libs"
REQUIRED_USE="plplot? ( high-level )"
RDEPEND="
x11-libs/gtk+:3
plplot? ( >=sci-libs/plplot-5.13.0[cairo,fortran] )
"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/fortran
virtual/pkgconfig
"
DOCS=( "README.md" "README-high-level.md" "CHANGELOG.md" )
pkg_setup() {
fortran-2_pkg_setup
}
src_prepare() {
default
# Fix library installation path and disable 'sketcher' build
sed -i -e "s:CMAKE_INSTALL_LIBDIR lib:CMAKE_INSTALL_LIBDIR $(get_libdir):" \
-e "s: add_subdirectory(sketcher)::" CMakeLists.txt || die
use !static-libs && eapply "${FILESDIR}/${P}_skip-static-build.patch"
cmake_src_prepare
}
src_configure() {
mycmakeargs+=(
-DEXCLUDE_PLPLOT=$(usex plplot false true)
-DNO_BUILD_HL=$(usex high-level false true)
-DINSTALL_EXAMPLES=$(usex examples)
-DNO_BUILD_EXAMPLES=true
)
cmake_src_configure
}
|
GitWeb
