1 files changed, 118 insertions, 0 deletions
diff --git a/net-p2p/transmission/transmission-9999.ebuild b/net-p2p/transmission/transmission-9999.ebuild
new file mode 100644
index 0000000..f19eddc
--- /dev/null
+++ b/net-p2p/transmission/transmission-9999.ebuild
@@ -0,0 +1,118 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /home/menelkir/portage/net-p2p/transmission/transmission-2.00b2.ebuild,v 1.1 2010/06/08 23:26:34 menelkir Exp $
+
+EAPI=2
+inherit autotools eutils fdo-mime gnome2-utils qt4-r2 subversion
+
+DESCRIPTION="A Fast, Easy and Free BitTorrent client"
+HOMEPAGE="http://www.transmissionbt.com/"
+ESVN_REPO_URI="svn://svn.transmissionbt.com/Transmission/trunk"
+ESVN_PROJECT="Transmission"
+ESVN_BOOTSTRAP="TZ=UTC svn log -v \"\${ESVN_REPO_URI}\" >\"\${S}\"/ChangeLog; NOCONFIGURE=1 ./autogen.sh"
+
+
+LICENSE="MIT GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd"
+IUSE="gnome gtk libnotify sound qt4"
+
+RDEPEND="
+	sys-libs/zlib
+	>=dev-libs/libevent-1.4.11
+	<dev-libs/libevent-2
+	>=dev-libs/openssl-0.9.4
+	|| ( >=net-misc/curl-7.16.3[ssl]
+		>=net-misc/curl-7.16.3[gnutls] )
+	gtk? ( >=dev-libs/glib-2.15.5:2
+		>=x11-libs/gtk+-2.12:2
+		>=dev-libs/dbus-glib-0.70
+		gnome? ( >=gnome-base/gconf-2.20.0 )
+		libnotify? ( >=x11-libs/libnotify-0.4.3 )
+		sound? ( >=media-libs/libcanberra-0.10 ) )
+	qt4? ( x11-libs/qt-gui:4 )"
+DEPEND="${RDEPEND}
+	>=sys-devel/libtool-2.2.6b
+	sys-devel/gettext
+	>=dev-util/intltool-0.40
+	dev-util/pkgconfig
+	sys-apps/sed"
+
+src_prepare() {
+	sed -i \
+		-e 's:-g -O0::g' \
+		-e 's:-g -O3::g' \
+		-e 's:-ggdb3::g' \
+		configure.ac || die
+
+	sed -i \
+		-e 's:$${TRANSMISSION_TOP}/third-party/libevent/.libs/libevent.a:-levent:' \
+		qt/qtr.pro || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf="--disable-libnotify --disable-libcanberra --disable-libgconf"
+
+	if use gtk; then
+		myconf="$(use_enable libnotify)
+			$(use_enable sound libcanberra)
+			$(use_enable gnome libgconf)"
+	fi
+
+	# cli and daemon doesn't have external deps
+	econf \
+		--disable-dependency-tracking \
+		$(use_enable gtk) \
+		--enable-cli \
+		--enable-daemon \
+		${myconf}
+
+	if use qt4; then
+		cd qt
+		eqmake4 qtr.pro
+	fi
+}
+
+src_compile() {
+	emake || die
+
+	if use qt4; then
+		cd qt
+		emake || die
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	dodoc AUTHORS NEWS qt/README.txt
+	rm -f "${D}"/usr/share/${PN}/web/LICENSE
+
+	# these are likely outdated for 1.83
+	newinitd "${FILESDIR}"/${PN}-daemon.initd.2 ${PN}-daemon || die
+	newconfd "${FILESDIR}"/${PN}-daemon.confd.1 ${PN}-daemon || die
+
+	if use qt4; then
+		cd qt
+		emake INSTALL_ROOT="${D}/usr" install || die
+		make_desktop_entry qtr "Transmission Qt BitTorrent Client" ${PN} \
+			"Network;FileTransfer;P2P;Qt"
+		use gtk || doicon qt/icons/transmission.png
+	fi
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}