blob: 545e40c6c2ecd654ab22db1ebbaea5be4dc26661 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit flag-o-matic xdg-utils vala
DESCRIPTION="Unified widget and session management libs for Xfce"
HOMEPAGE="
https://docs.xfce.org/xfce/libxfce4ui/start
https://gitlab.xfce.org/xfce/libxfce4ui/
"
SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
LICENSE="LGPL-2+ GPL-2+"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="glade +introspection startup-notification system-info vala wayland"
REQUIRED_USE="vala? ( introspection )"
DEPEND="
>=dev-libs/glib-2.66.0
>=x11-libs/gtk+-3.24.41-r1:3[introspection?,wayland?,X]
x11-libs/libX11
x11-libs/libICE
x11-libs/libSM
>=xfce-base/libxfce4util-4.17.2:=[introspection?,vala?]
>=xfce-base/xfconf-4.12:=
glade? ( dev-util/glade:3.10 )
introspection? ( >=dev-libs/gobject-introspection-1.66:= )
startup-notification? ( x11-libs/startup-notification )
system-info? (
dev-libs/libgudev
gnome-base/libgtop
>=media-libs/libepoxy-1.2
)
"
RDEPEND="
${DEPEND}
"
BDEPEND="
dev-lang/perl
dev-util/intltool
sys-devel/gettext
virtual/pkgconfig
vala? ( $(vala_depend) )
"
src_configure() {
# defang automagic dependencies, bug #873520
use wayland || append-cflags -DGENTOO_GTK_HIDE_WAYLAND
local myconf=(
$(use_enable introspection)
$(use_enable system-info glibtop)
$(use_enable system-info epoxy)
$(use_enable system-info gudev)
$(use_enable startup-notification)
$(use_enable vala)
$(use_enable glade gladeui2)
--with-vendor-info=Gentoo
)
use vala && vala_setup
econf "${myconf[@]}"
}
src_install() {
emake -j1 DESTDIR="${D}" install
find "${D}" -name '*.la' -delete || die
}
pkg_postinst() {
xdg_icon_cache_update
}
pkg_postrm() {
xdg_icon_cache_update
}
|
GitWeb