sys-kernel/dracut-crypt-ssh/dracut-crypt-ssh-1.0.7.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit toolchain-funcs

DESCRIPTION="Early unlocking of encrypted systems via ssh for dracut"
HOMEPAGE="https://github.com/dracut-crypt-ssh/dracut-crypt-ssh"
SRC_URI="https://github.com/dracut-crypt-ssh/dracut-crypt-ssh/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

DEPEND="sys-kernel/dracut"
RDEPEND="${DEPEND}
	|| (
		net-misc/connman
		net-misc/dhcp
		net-misc/dhcpcd
		net-misc/netifrc
		net-misc/networkmanager
		sys-apps/systemd
	)
	net-misc/dropbear"

PATCHES=( "${FILESDIR}"/${P}-makefile.patch )

src_prepare() {
	default

	# Fix libdir (hard-coded to "lib64")
	sed "s@/lib64/@/$(get_libdir)/@" \
		-i modules/60crypt-ssh/module-setup.sh \
		|| die
}

src_configure() {
	tc-export CC
	default
}