blob: e44c4bc2efa1fdfa86a0d6e5792b2d49cd1ee82d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=5
inherit eutils toolchain-funcs
DESCRIPTION="HFS FS Access utils"
HOMEPAGE="http://www.mars.org/home/rob/proj/hfs/"
SRC_URI="ftp://ftp.mars.org/pub/hfs/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ~arm ppc ppc64 sparc x86"
IUSE="tcl tk"
DEPEND="
tcl? ( dev-lang/tcl:0= )
tk? ( dev-lang/tk:0= )"
RDEPEND="${DEPEND}"
# use tk requires tcl - bug #150437
REQUIRED_USE="tk? ( tcl )"
src_prepare() {
epatch \
"${FILESDIR}"/${P}-errno.patch \
"${FILESDIR}"/largerthan2gb.patch \
"${FILESDIR}"/${P}-fix-tcl-8.6.patch
}
src_configure() {
econf $(use_with tcl) $(use_with tk)
}
src_compile() {
emake AR="$(tc-getAR) rc" CC="$(tc-getCC)" RANLIB="$(tc-getRANLIB)"
emake CC="$(tc-getCC)" -C hfsck
}
src_install() {
dodir /usr/bin /usr/lib /usr/share/man/man1
emake \
prefix="${D}"/usr \
MANDEST="${D}"/usr/share/man \
infodir="${D}"/usr/share/info \
install
dobin hfsck/hfsck
dodoc BLURB CHANGES README TODO doc/*.txt
}
|
GitWeb
