blob: c3dfde8bfa0014cdaa37759ce59b0aa094625ea8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
MY_P="${PN}-3-${PV}"
inherit scons-utils toolchain-funcs user flag-o-matic
DESCRIPTION="Synchronous multi-master replication engine that provides the wsrep API"
HOMEPAGE="http://www.galeracluster.com"
SRC_URI="http://releases.galeracluster.com/source/galera-3-${PV}.tar.gz"
LICENSE="GPL-2 BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
IUSE="cpu_flags_x86_sse4_2 garbd test"
CDEPEND="
dev-libs/openssl:0=
>=dev-libs/boost-1.41:0=
"
DEPEND="${DEPEND}
${CDEPEND}
dev-libs/check
>=sys-devel/gcc-4.4
>=dev-cpp/asio-1.10.1[ssl]
"
#Run time only
RDEPEND="${CDEPEND}"
S="${WORKDIR}/${MY_P}"
# Respect {C,LD}FLAGS.
PATCHES=( "${FILESDIR}/galera-3.15-strip-extra-cflags.patch" )
pkg_preinst() {
if use garbd ; then
enewgroup garbd
enewuser garbd -1 -1 -1 garbd
fi
}
src_prepare() {
default
# Remove bundled dev-cpp/asio
rm -r "${S}/asio" || die
#Remove optional garbd daemon
if ! use garbd ; then
rm -r "${S}/garb" || die
fi
}
src_configure() {
tc-export CC CXX
# Uses hardware specific code that seems to depend on SSE4.2
if use cpu_flags_x86_sse4_2 ; then
append-cflags -msse4.2
else
append-cflags -DCRC32C_NO_HARDWARE
fi
# strict_build_flags=0 disables -Werror, -pedantic, -Weffc++,
# and -Wold-style-cast
MYSCONS=(
ssl=1
tests=$(usex test 1 0)
strict_build_flags=0
)
}
src_compile() {
escons --warn=no-missing-sconscript "${MYSCONS[@]}"
}
src_install() {
dodoc scripts/packages/README scripts/packages/README-MySQL
if use garbd ; then
dobin garb/garbd
newconfd "${FILESDIR}/garb.cnf" garbd
newinitd "${FILESDIR}/garb.sh" garbd
doman man/garbd.8
fi
exeinto /usr/$(get_libdir)/${PN}
doexe libgalera_smm.so
}
|
GitWeb