blob: f7417ab49bf5dede0a068575da9e46cbe0eb30c2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
COMMIT=f414794a168712f72884cdcfba818def5f42e721
inherit cmake-utils
DESCRIPTION="Advanced molecule editor and visualizer 2 - libraries"
HOMEPAGE="https://www.openchemistry.org/"
SRC_URI="https://github.com/OpenChemistry/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz
vtk? ( https://github.com/psavery/genXrdPattern/releases/download/1.0-static/linux64-genXrdPattern )"
SLOT="0"
LICENSE="BSD GPL-2+"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="archive doc hdf5 qt5 static-plugins test vtk"
REQUIRED_USE="vtk? ( qt5 )"
# TODO: Not yet packaged:
# sci-libs/libmsym (https://github.com/mcodev31/libmsym)
# sci-libs/spglib (https://atztogo.github.io/spglib/)
RDEPEND="
dev-libs/jsoncpp:=
>=sci-chemistry/molequeue-0.7
archive? ( app-arch/libarchive )
hdf5? ( sci-libs/hdf5:= )
qt5? (
dev-qt/qtconcurrent:5
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtnetwork:5
dev-qt/qtwidgets:5
media-libs/glew:0=
virtual/opengl
)
vtk? ( sci-libs/vtk[qt5] )
"
DEPEND="${RDEPEND}
dev-cpp/eigen:3
test? ( dev-cpp/gtest )"
S="${WORKDIR}/${PN}-${COMMIT}"
PATCHES=(
"${FILESDIR}"/${PN}-0.7.2-6464.patch
"${FILESDIR}/"${P}-underlinking.patch
"${FILESDIR}/"${P}-unbundle-jsoncpp.patch
"${FILESDIR}/"${P}-bundled-genxrdpattern.patch
)
src_unpack() {
unpack ${P}.tar.gz
if use vtk; then
cp "${DISTDIR}"/linux64-genXrdPattern "${WORKDIR}/genXrdPattern" || die
fi
}
src_configure() {
local mycmakeargs=(
-DUSE_PROTOCALL=OFF
-DBUILD_GPL_PLUGINS=ON
-DUSE_MOLEQUEUE=ON
-DUSE_LIBMSYM=OFF
-DUSE_LIBSPG=OFF
-DUSE_PYTHON=OFF
-DUSE_LIBARCHIVE=$(usex archive)
-DBUILD_DOCUMENTATION=$(usex doc)
-DUSE_HDF5=$(usex hdf5)
-DUSE_OPENGL=$(usex qt5)
-DUSE_QT=$(usex qt5)
-DBUILD_STATIC_PLUGINS=$(usex static-plugins)
-DENABLE_TESTING=$(usex test)
-DUSE_VTK=$(usex vtk)
)
use vtk && mycmakeargs+=(
-DBUNDLED_GENXRDPATTERN="${WORKDIR}/genXrdPattern"
)
cmake-utils_src_configure
}
|
GitWeb