blob: 3e5b6c4c47d1d625561f9f2fea28249a699536bb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
KDE_HANDBOOK="optional"
KDE_TEST="true"
VIRTUALX_REQUIRED="test"
inherit kde5
DESCRIPTION="Kate is an advanced text editor"
HOMEPAGE="https://www.kde.org/applications/utilities/kate https://kate-editor.org/"
KEYWORDS="~amd64 ~x86"
IUSE="+addons"
DEPEND="
$(add_frameworks_dep kactivities)
$(add_frameworks_dep kcodecs)
$(add_frameworks_dep kcompletion)
$(add_frameworks_dep kconfig)
$(add_frameworks_dep kconfigwidgets)
$(add_frameworks_dep kcoreaddons)
$(add_frameworks_dep kcrash)
$(add_frameworks_dep kdbusaddons)
$(add_frameworks_dep kguiaddons)
$(add_frameworks_dep ki18n)
$(add_frameworks_dep kiconthemes)
$(add_frameworks_dep kio)
$(add_frameworks_dep kitemmodels)
$(add_frameworks_dep kitemviews)
$(add_frameworks_dep kjobwidgets)
$(add_frameworks_dep kparts)
$(add_frameworks_dep kservice)
$(add_frameworks_dep ktexteditor)
$(add_frameworks_dep ktextwidgets)
$(add_frameworks_dep kwidgetsaddons)
$(add_frameworks_dep kwindowsystem)
$(add_frameworks_dep kxmlgui)
$(add_qt_dep qtdbus)
$(add_qt_dep qtgui)
$(add_qt_dep qtwidgets)
$(add_qt_dep qtxml)
addons? (
$(add_frameworks_dep kbookmarks)
$(add_frameworks_dep knewstuff)
$(add_frameworks_dep kwallet)
$(add_frameworks_dep plasma)
$(add_frameworks_dep threadweaver)
$(add_qt_dep qtsql)
)
"
RDEPEND="${DEPEND}
!kde-misc/ktexteditorpreviewplugin
"
src_prepare() {
kde5_src_prepare
# test hangs
sed -e "/session_manager_test/d" -i kate/autotests/CMakeLists.txt || die
# delete colliding kwrite translations
if [[ ${KDE_BUILD_TYPE} = release ]]; then
find po -type f -name "*po" -and -name "kwrite*" -delete || die
rm -rf po/*/docs/kwrite || die
fi
}
src_configure() {
local mycmakeargs=(
-DBUILD_addons=$(usex addons)
-DBUILD_kwrite=FALSE
)
kde5_src_configure
}
pkg_postinst() {
kde5_pkg_postinst
if [[ -z "${REPLACING_VERSIONS}" ]] && use addons; then
elog "The functionality of ktexteditorpreview plugin can be extended with:"
elog " kde-misc/kmarkdownwebview"
elog " media-gfx/kgraphviewer"
fi
}
|
GitWeb