blob: 844d7cf8bac306a0cc9fa15abc591261c3e2aecc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
LLVM_MAX_SLOT="17"
MY_PN="SPIRV-LLVM-Translator"
MY_P="${MY_PN}-${PV}"
inherit cmake flag-o-matic llvm multiprocessing
DESCRIPTION="Bi-directional translator between SPIR-V and LLVM IR"
HOMEPAGE="https://github.com/KhronosGroup/SPIRV-LLVM-Translator"
SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${MY_P}"
LICENSE="UoI-NCSA"
SLOT="$(ver_cut 1)"
KEYWORDS="amd64 arm64 ~riscv x86"
IUSE="test"
RESTRICT="!test? ( test )"
RDEPEND="
dev-util/spirv-tools
sys-devel/llvm:${SLOT}=
"
DEPEND="${RDEPEND}
>=dev-util/spirv-headers-1.3.275
"
BDEPEND="
virtual/pkgconfig
test? (
dev-python/lit
sys-devel/clang:${SLOT}
)
"
PATCHES=(
"${FILESDIR}"/${P}-intel-capability.patch
"${FILESDIR}"/${P}-do-not-rely-on-version-of-compiler-being-VER.0.0-219.patch
)
src_prepare() {
append-flags -fPIC
cmake_src_prepare
# https://github.com/KhronosGroup/SPIRV-LLVM-Translator/pull/2555
sed -i -e 's/%triple/x86_64-unknown-linux-gnu/' test/DebugInfo/X86/*.ll || die
}
src_configure() {
local mycmakeargs=(
-DCCACHE_ALLOWED="OFF"
-DCMAKE_INSTALL_PREFIX="$(get_llvm_prefix ${LLVM_MAX_SLOT})"
-DLLVM_EXTERNAL_SPIRV_HEADERS_SOURCE_DIR="${ESYSROOT}/usr/include/spirv"
-DLLVM_SPIRV_INCLUDE_TESTS=$(usex test "ON" "OFF")
-Wno-dev
)
cmake_src_configure
}
src_test() {
lit -vv "-j${LIT_JOBS:-$(makeopts_jobs)}" "${BUILD_DIR}/test" || die
}
|
GitWeb
