blob: 16b017e9f0505d4bc6196b9f05aea30dc4e27e85 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python2_7 python3_6 )
PYTHON_REQ_USE="threads(+)"
inherit distutils-r1
TWISTED_PN="Twisted"
TWISTED_P="${TWISTED_PN}-${PV}"
TWISTED_RELEASE=$(ver_cut 1-2)
DESCRIPTION="An asynchronous networking framework written in Python"
HOMEPAGE="https://www.twistedmatrix.com/trac/"
SRC_URI="https://twistedmatrix.com/Releases/${TWISTED_PN}"
SRC_URI="${SRC_URI}/${TWISTED_RELEASE}/${TWISTED_P}.tar.bz2
https://dev.gentoo.org/~mgorny/dist/twisted-regen-cache.gz"
# Dropped keywords due to new deps not keyworded
#KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~x86 ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~x86"
LICENSE="MIT"
SLOT="0"
IUSE="conch crypt http2 serial +soap test"
RESTRICT="!test? ( test )"
# openssh-7.6_p1 test failures: bug https://twistedmatrix.com/trac/ticket/9311
RDEPEND="
>=dev-python/incremental-16.10.1[${PYTHON_USEDEP}]
>=dev-python/zope-interface-4.4.2[${PYTHON_USEDEP}]
conch? (
dev-python/pyasn1[${PYTHON_USEDEP}]
>=dev-python/cryptography-1.5.0[${PYTHON_USEDEP}]
>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
)
crypt? (
>=dev-python/pyopenssl-16.0.0[${PYTHON_USEDEP}]
dev-python/service_identity[${PYTHON_USEDEP}]
>=dev-python/idna-0.6[${PYTHON_USEDEP}]
)
serial? ( >=dev-python/pyserial-3.0[${PYTHON_USEDEP}] )
soap? ( $(python_gen_cond_dep 'dev-python/soappy[${PYTHON_USEDEP}]' python2_7) )
http2? (
>=dev-python/hyper-h2-3.0.0[${PYTHON_USEDEP}]
<dev-python/hyper-h2-4.0.0[${PYTHON_USEDEP}]
>=dev-python/priority-1.1.0[${PYTHON_USEDEP}]
<dev-python/priority-2.0[${PYTHON_USEDEP}]
)
>=dev-python/constantly-15.1.0[${PYTHON_USEDEP}]
>=dev-python/automat-0.3.0[${PYTHON_USEDEP}]
>=dev-python/hyperlink-17.1.1[${PYTHON_USEDEP}]
!dev-python/twisted-core
!dev-python/twisted-conch
!dev-python/twisted-lore
!dev-python/twisted-mail
!dev-python/twisted-names
!dev-python/twisted-news
!dev-python/twisted-pair
!dev-python/twisted-runner
!dev-python/twisted-words
!dev-python/twisted-web
"
DEPEND="
>=dev-python/incremental-16.10.1[${PYTHON_USEDEP}]
test? (
dev-python/gmpy[${PYTHON_USEDEP}]
dev-python/pyasn1[${PYTHON_USEDEP}]
>=dev-python/cryptography-0.9.1[${PYTHON_USEDEP}]
>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
>=dev-python/pyopenssl-0.13[${PYTHON_USEDEP}]
dev-python/service_identity[${PYTHON_USEDEP}]
dev-python/idna[${PYTHON_USEDEP}]
dev-python/pyserial[${PYTHON_USEDEP}]
>=dev-python/constantly-15.1.0[${PYTHON_USEDEP}]
<net-misc/openssh-7.6
)
"
PATCHES=(
# ${PN}-17.9.0-Fix-test-on-Python-363.patch" <== version specific from upstream
# Respect TWISTED_DISABLE_WRITING_OF_PLUGIN_CACHE variable.
"${FILESDIR}/${PN}-18.4.0-Disable-writing-of-plugin-cache.patch"
"${FILESDIR}/test_main.patch"
"${FILESDIR}/utf8_overrides.patch"
"${FILESDIR}/${PN}-16.6.0-test-fixes.patch"
"${FILESDIR}/${PN}-17.9.0-python-27-utf-8-fix.patch"
)
S=${WORKDIR}/${TWISTED_P}
python_prepare_all() {
# disable tests that don't work in our sandbox
# and other test failures due to our conditions
if use test ; then
# Remove since this is an upstream distribution test for making releases
rm src/twisted/python/test/test_release.py || die "rm src/twisted/python/test/test_release.py FAILED"
fi
distutils-r1_python_prepare_all
}
python_compile() {
if ! python_is_python3; then
# Needed to make the sendmsg extension work
# (see https://twistedmatrix.com/trac/ticket/5701 )
local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
local -x CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
fi
distutils-r1_python_compile
}
python_test() {
distutils_install_for_testing
export EMERGE_TEST_OVERRIDE=1
export UTF8_OVERRIDES=1
unset TWISTED_DISABLE_WRITING_OF_PLUGIN_CACHE
# workaround for the eclass not installing the entry points
# in the test environment. copy the old 16.3.2 start script
# to run the tests with
cp "${FILESDIR}"/trial "${TEST_DIR}" || die
chmod +x "${TEST_DIR}"/trial || die
pushd "${TEST_DIR}" > /dev/null || die
if ! "${TEST_DIR}"/trial twisted; then
die "Tests failed with ${EPYTHON}"
fi
# due to an anomoly in the tests, python doesn't return the correct form
# of the escape sequence. So run those test separately with a clean python interpreter
export UTF8_OVERRIDES=0
if ! "${TEST_DIR}"/trial twisted.test.test_twistd.DaemonizeTests; then
die "DaemonizeTests failed with ${EPYTHON}"
fi
if ! "${TEST_DIR}"/trial twisted.test.test_reflect.SafeStrTests; then
die "SafeStrTests failed with ${EPYTHON}"
fi
popd > /dev/null || die
}
python_install() {
distutils-r1_python_install
cd "${D}$(python_get_sitedir)" || die
# own the dropin.cache so we don't leave orphans
touch twisted/plugins/dropin.cache || die
python_doscript "${WORKDIR}"/twisted-regen-cache
}
python_install_all() {
distutils-r1_python_install_all
newconfd "${FILESDIR}/twistd.conf" twistd
newinitd "${FILESDIR}/twistd.init" twistd
}
python_postinst() {
twisted-regen-cache || die
}
pkg_postinst() {
python_foreach_impl python_postinst
einfo "Install complete"
if use test ; then
einfo ""
einfo "Some tests have been disabled during testing due to"
einfo "known incompatibilities with the emerge sandboxes and/or"
einfo "not runnable as the root user."
einfo "For a complete test suite run on the code."
einfo "Run the tests as a normal user for each python it is installed to."
einfo " ie: $ python3.6 /usr/bin/trial twisted"
fi
}
python_postrm() {
rm -f "${ROOT}$(python_get_sitedir)/twisted/plugins/dropin.cache" || die
}
pkg_postrm() {
# if we're removing the last version, remove the cache file
if [[ ! ${REPLACING_VERSIONS} ]]; then
python_foreach_impl python_postrm
fi
}
|
GitWeb