blob: f0f244bd48ceec6408b47a9f1079ce20b234542a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=5
PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy pypy3 )
inherit distutils-r1
MY_PN="redis"
MY_P="${MY_PN}-${PV}"
DESCRIPTION="Python client for Redis key-value store"
HOMEPAGE="https://github.com/andymccurdy/redis-py"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="amd64 ~arm ~arm64 hppa ppc ppc64 x86 ~amd64-linux ~x86-linux"
IUSE="test"
RDEPEND=""
DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
test? ( dev-db/redis
>=dev-python/pytest-2.5.0[${PYTHON_USEDEP}] )"
S="${WORKDIR}/${MY_P}"
PATCHES=(
"${FILESDIR}"/${P}-test-finalize.patch
)
python_prepare_all() {
distutils-r1_python_prepare_all
# Make sure that tests will be used from BUILD_DIR rather than cwd.
mv tests tests-hidden || die
# Correct local import patch syntax
sed -e 's:from .conftest:from conftest:' \
-i tests-hidden/{test_connection_pool.py,test_commands.py,test_encoding.py,test_pubsub.py} \
|| die
}
python_compile() {
distutils-r1_python_compile
if use test; then
cp -r tests-hidden "${BUILD_DIR}"/tests || die
fi
}
python_test() {
local sock="${T}/redis.sock"
"${EPREFIX}/usr/sbin/redis-server" - <<- EOF
daemonize yes
pidfile "${T}/redis.pid"
unixsocket ${sock}
EOF
PYTHONPATH="${S}:${S}/tests-hidden"
esetup.py test --verbose
kill $(<"${T}/redis.pid")
}
|
GitWeb
