blob: 325450e4dc5f62534f533e3d5dd7bab3b45852dd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="8"
USE_RUBY="ruby27 ruby30 ruby31"
inherit ruby-single toolchain-funcs
DESCRIPTION="A clean C Library for processing UTF-8 Unicode data"
HOMEPAGE="https://github.com/JuliaStrings/utf8proc"
SRC_URI="https://github.com/JuliaStrings/${PN#lib}/archive/v${PV}.tar.gz -> ${P}.tar.gz
cjk? ( https://dev.gentoo.org/~hattya/distfiles/${PN}-EastAsianWidth-15.0.0.xz )"
LICENSE="MIT"
SLOT="0/${PV}"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~x64-macos"
IUSE="cjk static-libs test"
RESTRICT="!test? ( test )"
BDEPEND="test? (
=app-i18n/unicode-data-15.0*
${RUBY_DEPS}
)"
S="${WORKDIR}/${P#lib}"
QA_PKGCONFIG_VERSION="$(ver_cut 1).6.0"
src_prepare() {
if use cjk; then
einfo "Modifying East Asian Ambiguous (A) as wide ..."
cp "${WORKDIR}"/${PN}-EastAsianWidth-15.0.0 ${PN#lib}_data.c || die
fi
sed -i "/^libdir/s:/lib:/$(get_libdir):" Makefile
default
}
src_compile() {
emake \
AR="$(tc-getAR)" \
CC="$(tc-getCC)" \
prefix="${EPREFIX}/usr"
}
src_test() {
cp "${BROOT}"/usr/share/unicode-data/{DerivedCoreProperties,{Normalization,auxiliary/GraphemeBreak}Test}.txt data || die
emake CC="$(tc-getCC)" check
}
src_install() {
emake \
DESTDIR="${D}" \
prefix="${EPREFIX}/usr" \
install
use static-libs || find "${ED}" -name '*.a' -delete || die
}
|
GitWeb
