blob: 15eaeafd009dc8e1ea3d405e9d0cf55785f26b62 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools
DESCRIPTION="Creation/expansion of ISO-9660 filesystems on CD/DVD media supported by libburn"
HOMEPAGE="https://dev.lovelyhq.com/libburnia/web/wiki/Libisoburn"
SRC_URI="https://files.libburnia-project.org/releases/${P}.tar.gz"
LICENSE="GPL-2 GPL-3"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86"
IUSE="acl debug external-filters external-filters-setuid frontend-optional
launch-frontend launch-frontend-setuid libedit readline static-libs xattr zlib"
REQUIRED_USE="frontend-optional? ( || ( launch-frontend launch-frontend-setuid ) )"
BDEPEND="
virtual/pkgconfig
"
RDEPEND="
>=dev-libs/libburn-1.5.6
>=dev-libs/libisofs-1.5.6
readline? ( sys-libs/readline:0= )
!readline? (
libedit? ( dev-libs/libedit )
)
acl? ( virtual/acl )
xattr? ( sys-apps/attr )
zlib? ( sys-libs/zlib )
launch-frontend? (
dev-lang/tcl:0
dev-lang/tk:0
)
launch-frontend-setuid? (
dev-lang/tcl:0
dev-lang/tk:0
)
frontend-optional? ( dev-tcltk/bwidget )
"
DEPEND="
${RDEPEND}
"
src_prepare() {
default
# Ancient libtool version in 1.5.6 at least (debian's 2.4.2-1.11)
eautoreconf
}
src_configure() {
econf \
$(use_enable static-libs static) \
$(use_enable readline libreadline) \
$(usex readline --disable-libedit $(use_enable libedit)) \
$(use_enable acl libacl) \
$(use_enable xattr) \
$(use_enable zlib) \
--disable-libjte \
$(use_enable external-filters) \
$(use_enable external-filters-setuid) \
$(use_enable launch-frontend) \
$(use_enable launch-frontend-setuid) \
--disable-ldconfig-at-install \
--enable-pkg-check-modules \
$(use_enable debug)
}
src_install() {
default
dodoc CONTRIBUTORS doc/{comments,*.wiki,startup_file.txt}
docinto frontend
dodoc frontend/README-tcltk
docinto xorriso
dodoc xorriso/{changelog.txt,README_gnu_xorriso}
find "${D}" -name '*.la' -delete || die
}
|
GitWeb