blob: e822eb2d141e80e9a4c621b247ff63fdb82a4816 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit unpacker eapi7-ver
SUPER_PN='amdgpu-pro'
MY_PV=$(ver_rs 2 '-')
DESCRIPTION="Proprietary OpenCL implementation for AMD GPUs"
HOMEPAGE="https://support.amd.com/en-us/kb-articles/Pages/Radeon-Software-for-Linux-Release-Notes.aspx"
SRC_URI="${SUPER_PN}-${MY_PV}.tar.xz"
LICENSE="AMD-GPU-PRO-EULA"
SLOT="0"
KEYWORDS="~amd64"
RESTRICT="mirror fetch strip"
DEPEND="dev-util/patchelf"
RDEPEND="dev-libs/ocl-icd"
QA_PREBUILT="/opt/${SUPER_PN}/lib*/*"
S="${WORKDIR}/${SUPER_PN}-${MY_PV}"
pkg_nofetch() {
local pkgver=$(ver_cut 1-2)
einfo "Please download the Radeon Software for Linux Driver ${pkgver} for Ubuntu from"
einfo " ${HOMEPAGE}"
einfo "The archive should then be placed into ${DISTDIR}."
}
src_unpack() {
default
local ids_ver="1.0.0"
local libdrm_ver="2.4.82"
local patchlevel=$(ver_cut 3)
cd "${S}" || die
unpack_deb opencl-${SUPER_PN}-icd_${MY_PV}_amd64.deb
unpack_deb libdrm-amdgpu-amdgpu1_${libdrm_ver}-${patchlevel}_amd64.deb
unpack_deb ids-amdgpu_${ids_ver}-${patchlevel}_all.deb
}
src_prepare() {
default
cd "${S}/opt/${SUPER_PN}/lib/x86_64-linux-gnu" || die
patchelf --set-rpath '$ORIGIN' libamdocl64.so || die "Failed to fix library rpath"
}
src_install() {
into "/opt/amdgpu"
dolib opt/${SUPER_PN}/lib/x86_64-linux-gnu/*
dolib opt/amdgpu/lib/x86_64-linux-gnu/*
insinto "/opt/amdgpu"
doins -r opt/amdgpu/share
insinto /etc/OpenCL/vendors/
echo "/opt/amdgpu/$(get_libdir)/libamdocl64.so" > "${SUPER_PN}.icd" || die "Failed to generate ICD file"
doins "${SUPER_PN}.icd"
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
ewarn "Please note that using proprietary OpenCL libraries together with the"
ewarn "Open Source amdgpu stack is not officially supported by AMD. Do not ask them"
ewarn "for support in case of problems with this package."
ewarn ""
ewarn "Furthermore, if you have the whole AMDGPU-Pro stack installed this package"
ewarn "will almost certainly conflict with it. This might change once AMDGPU-Pro"
ewarn "has become officially supported by Gentoo."
fi
elog "AMD OpenCL driver relies on dev-libs/ocl-icd to work. To enable it, please run"
elog ""
elog " eselect opencl set ocl-icd"
elog ""
}
|
GitWeb