blob: 4463e0ba5f360bd624a55bac52ce41e90189cc36 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit gnome2
DESCRIPTION="Compiler for the GObject type system"
HOMEPAGE="https://wiki.gnome.org/Projects/Vala"
LICENSE="LGPL-2.1+"
SLOT="0.50"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x86-linux"
IUSE="test valadoc"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-libs/glib-2.48.0:2
>=dev-libs/vala-common-${PV}
valadoc? ( >=media-gfx/graphviz-2.16 )
!<net-libs/libsoup-2.66.2[vala]
" # Older libsoup generates a libsoup-2.4.vapi that isn't fine for vala:0.46 anymore
# We block here, so libsoup[vala] consumers wouldn't have to >= it, which would be bad
# as the newer is not required with older vala when those are picked instead of 0.46.
# vala-0.45.91 ships a broken libsoup-2.4.vapi copy too, but that'll be fixed by 0.45.92
DEPEND="${RDEPEND}
test? (
dev-libs/dbus-glib
>=dev-libs/glib-2.26:2
dev-libs/gobject-introspection
)
"
BDEPEND="
dev-libs/libxslt
sys-devel/flex
virtual/pkgconfig
virtual/yacc
"
src_configure() {
# weasyprint enables generation of PDF from HTML
gnome2_src_configure \
--disable-unversioned \
$(use_enable valadoc) \
VALAC=: \
WEASYPRINT=:
}
src_install() {
default
find "${D}" -name "*.la" -delete || die
}
|
GitWeb
