blob: e84aeae04dfdc2b3b4b3165640e5685e14faa537 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
inherit gnome.org meson-multilib python-any-r1
DESCRIPTION="C++ interface for glib2"
HOMEPAGE="https://www.gtkmm.org https://gitlab.gnome.org/GNOME/glibmm"
LICENSE="LGPL-2.1+"
SLOT="2.68"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
IUSE="gtk-doc debug test"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-libs/glib-2.73.2:2[${MULTILIB_USEDEP}]
dev-libs/libsigc++:3[gtk-doc?,${MULTILIB_USEDEP}]
"
DEPEND="${RDEPEND}"
BDEPEND="
${PYTHON_DEPS}
virtual/pkgconfig
gtk-doc? (
app-text/doxygen[dot]
dev-lang/perl
dev-libs/libxslt
)
"
src_prepare() {
default
# giomm_tls_client requires FEATURES=-network-sandbox and glib-networking rdep
sed -i -e '/giomm_tls_client/d' tests/meson.build || die
if ! use test; then
sed -i -e "/^subdir('tests')/d" meson.build || die
fi
}
multilib_src_configure() {
local emesonargs=(
-Dwarnings=min
-Dbuild-deprecated-api=true
$(meson_native_use_bool gtk-doc build-documentation)
$(meson_use debug debug-refcounting)
-Dbuild-examples=false
)
meson_src_configure
}
|
GitWeb
