1 files changed, 57 insertions, 0 deletions
diff --git a/media-sound/qsampler/qsampler-0.9.9.ebuild b/media-sound/qsampler/qsampler-0.9.9.ebuild
new file mode 100644
index 000000000000..38a795222015
--- /dev/null
+++ b/media-sound/qsampler/qsampler-0.9.9.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://git.code.sf.net/p/qsampler/code"
+	inherit git-r3
+else
+	SRC_URI="mirror://sourceforge/${PN}/${PV}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Graphical frontend to the LinuxSampler engine"
+HOMEPAGE="https://qsampler.sourceforge.io/ https://www.linuxsampler.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="debug +libgig"
+
+DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-libs/alsa-lib
+	media-libs/liblscp:=
+	x11-libs/libX11
+	libgig? ( media-libs/libgig:= )
+"
+RDEPEND="${DEPEND}
+	media-sound/linuxsampler
+"
+BDEPEND="dev-qt/linguist-tools:5"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.9.1-cmake-no-git.patch"
+)
+
+DOCS=( ChangeLog README TRANSLATORS )
+
+src_prepare() {
+	cmake_src_prepare
+
+	sed -e "/^find_package.*QT/s/Qt6 //" -i CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCONFIG_DEBUG=$(usex debug 1 0)
+		-DCONFIG_LIBGIG=$(usex libgig 1 0)
+	)
+	cmake_src_configure
+}