3 files changed, 51 insertions, 2 deletions
diff --git a/dev-util/objconv/Manifest b/dev-util/objconv/Manifest
index 2bc31bc891d8..b1593a00a9dc 100644
--- a/dev-util/objconv/Manifest
+++ b/dev-util/objconv/Manifest
@@ -1 +1,2 @@
 DIST objconv-2.42.zip 1016499 BLAKE2B fec4a386b3d8e0e870066098353c33d78e6b027de1f0183d568479ce508b2c10b020ab3de47d1d24481ddc785be5ee1d0b8053ec354bb23dd317a6e08de8c1a4 SHA512 9ccc49ddfe5a6d353c746917832419478335e73d1cb85762cad314f918532bd20844b9812e392d57789a4a6cb8764945a6b1894884b50d5486bdf635fe58d35f
+DIST objconv-2.51.zip 1033450 BLAKE2B 1029e8001bee969f177e7e47e735dc132dbf640bb472ae148cd2a33af522c190066f226a55da3bb3b47902a68eecf437edc025622781bda691a10956c84561c3 SHA512 12991b98fafbb5fad709471b25bf8acd2944f862ca1f3cbae5a6f7fd53a6009dbb6e67a2fcfa180965b519a2d6010d9b2f7585748ea58d36b28d86c0981f13d8
diff --git a/dev-util/objconv/objconv-2.42.ebuild b/dev-util/objconv/objconv-2.42.ebuild
index f4aa2421d778..8555cd6bce35 100644
--- a/dev-util/objconv/objconv-2.42.ebuild
+++ b/dev-util/objconv/objconv-2.42.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2016 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=5
@@ -16,7 +16,7 @@ SLOT="0"
 KEYWORDS="~amd64 ~x86"
 
 RDEPEND=""
-DEPEND=""
+DEPEND="app-arch/unzip"
 
 S=${WORKDIR}/${P}
 
diff --git a/dev-util/objconv/objconv-2.51.ebuild b/dev-util/objconv/objconv-2.51.ebuild
new file mode 100644
index 000000000000..c4d8fb209631
--- /dev/null
+++ b/dev-util/objconv/objconv-2.51.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs unpacker
+
+DESCRIPTION="object code file converted (COFF, ELF, OMF, MACHO)"
+HOMEPAGE="http://agner.org/optimize/#objconv"
+# original URL is "http://agner.org/optimize/objconv.zip", but it's unversioned.
+# I copy those to distfiles time to time. last modified: 2018-Oct-07
+SRC_URI="https://dev.gentoo.org/~slyfox/distfiles/${P}.zip"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND=""
+DEPEND=""
+BDEPEND="app-arch/unzip"
+
+S=${WORKDIR}/${P}
+
+src_unpack() {
+	unpacker_src_unpack
+	mkdir "${S}" || die
+	pushd "${S}" || die
+	unpack_zip ../source.zip
+}
+
+src_prepare() {
+	default
+
+	# project has extremenly poor build system (see build.sh)
+	local sources=$(echo *.cpp)
+
+	{
+		echo "objconv: ${sources//.cpp/.o}"
+		echo "	\$(CXX) \$(CXXFLAGS) -o \$@ \$^ \$(LDFLAGS)"
+	} > Makefile || die
+
+	tc-export CXX
+}
+
+src_install() {
+	dobin objconv
+	dodoc ../objconv-instructions.pdf
+}