1 files changed, 46 insertions, 0 deletions
diff --git a/dev-python/flask-migrate/flask-migrate-4.0.6.ebuild b/dev-python/flask-migrate/flask-migrate-4.0.6.ebuild
new file mode 100644
index 000000000000..1ee6db65ab0a
--- /dev/null
+++ b/dev-python/flask-migrate/flask-migrate-4.0.6.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+MY_P="Flask-Migrate-${PV}"
+DESCRIPTION="SQLAlchemy database migrations for Flask applications using Alembic"
+HOMEPAGE="
+	https://github.com/miguelgrinberg/Flask-Migrate/
+	https://pypi.org/project/Flask-Migrate/
+"
+SRC_URI="
+	https://github.com/miguelgrinberg/Flask-Migrate/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/alembic-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-0.9[${PYTHON_USEDEP}]
+	>=dev-python/flask-sqlalchemy-1.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
+
+python_test() {
+	local -x PATH=${T}/bin:${PATH}
+
+	mkdir -p "${T}"/bin || die
+	cat > "${T}"/bin/flask <<-EOF || die
+		#!/bin/sh
+		exec ${EPYTHON} -m flask "\${@}"
+	EOF
+	chmod +x "${T}"/bin/flask || die
+
+	eunittest
+}