1 files changed, 56 insertions, 0 deletions
diff --git a/net-mail/fdm/fdm-2.2-r3.ebuild b/net-mail/fdm/fdm-2.2-r3.ebuild
new file mode 100644
index 000000000000..404b0182e72b
--- /dev/null
+++ b/net-mail/fdm/fdm-2.2-r3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Fetch, filter and deliver mail"
+HOMEPAGE="https://github.com/nicm/fdm"
+SRC_URI="https://github.com/nicm/fdm/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 x86"
+IUSE="examples pcre"
+
+DEPEND="
+	dev-libs/openssl:=
+	sys-libs/tdb
+	pcre? ( dev-libs/libpcre2 )
+"
+RDEPEND="
+	${DEPEND}
+	acct-group/fdm
+	acct-user/fdm
+"
+
+DOCS=( CHANGES README TODO MANUAL )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.2-configure-strlcpy.patch
+	"${FILESDIR}"/${P}-pcre2.patch
+	"${FILESDIR}"/${P}-uaf.patch
+)
+
+src_prepare() {
+	default
+
+	# Change user '_fdm' to 'fdm'
+	sed -e 's/_fdm/fdm/g' -i fdm.h || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable pcre pcre2)
+}
+
+src_install() {
+	default
+
+	if use examples ; then
+		docinto examples
+		dodoc examples/*
+	fi
+}