2 files changed, 78 insertions, 0 deletions
diff --git a/app-text/cherrytree/Manifest b/app-text/cherrytree/Manifest
index 8091cfa6e7b3..239a435ebca9 100644
--- a/app-text/cherrytree/Manifest
+++ b/app-text/cherrytree/Manifest
@@ -1 +1,2 @@
 DIST cherrytree_1.1.4.tar.xz 4714968 BLAKE2B 98cb6c20f5f957420b01352f3b1ba86768010e64583d94130e878eca747350c5eab11107ef3719c65f3a6126127b31e4d0e5807f90548f9f8819cd16f0f299f1 SHA512 053871386b4fd5e9964082421c63a10f332942fb1b29e5145b18858a1219ad55e108235dda279bdbf9b3516fd17502c55357e196a327232a6d82aaa1e06598d9
+DIST cherrytree_1.2.0.tar.xz 4735884 BLAKE2B 47f2aef52bb1fea23be8f5db3d2ec9f4c6a596bb6136350098f870688e34e5662241f188f1c94331af2119b59546c95fbe8254bdbb187990b514f9d21fd76214 SHA512 729e8227eb1f0616e110153ac2139cc7019ed5e1a949c8be40fd2235ee5d2e0f0b1925c57d72c9b443852e5b80a50793e4e903b7df41da8e95a172210f7ec035
diff --git a/app-text/cherrytree/cherrytree-1.2.0.ebuild b/app-text/cherrytree/cherrytree-1.2.0.ebuild
new file mode 100644
index 000000000000..b4acf9146aa5
--- /dev/null
+++ b/app-text/cherrytree/cherrytree-1.2.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit cmake python-any-r1 xdg
+
+DESCRIPTION="A hierarchical note taking application (C++ version)"
+HOMEPAGE="https://www.giuspen.com/cherrytree/"
+
+SRC_URI="https://github.com/giuspen/${PN}/releases/download/v$PV/${P/-/_}.tar.xz"
+S="${WORKDIR}"/${P/-/_}
+
+# GPL-3 — future/src/ct (CherryTree)
+# LGPL-2.1 — future/src/7za (7zip)
+# MIT — future/src/fmt (libfmt)
+LICENSE="GPL-3 LGPL-2.1 MIT"
+
+SLOT="0"
+
+KEYWORDS="~amd64 ~x86"
+
+IUSE="nls test"
+
+# Has deps that aren't available in ::gentoo repo
+RESTRICT="test"
+
+RDEPEND="app-i18n/uchardet
+	app-text/gspell:=
+	>=dev-cpp/glibmm-2.64.2:2
+	dev-cpp/gtkmm:3.0
+	x11-libs/gtksourceview:4
+	dev-cpp/libxmlpp:2.6
+	dev-cpp/pangomm:1.4
+	dev-db/sqlite:3
+	dev-libs/fribidi
+	dev-libs/glib:2
+	dev-libs/libfmt:=
+	dev-libs/libsigc++:2
+	dev-libs/libxml2:2
+	>=dev-libs/spdlog-1.5:=
+	>=x11-libs/vte-0.70.2:2.91
+	net-misc/curl
+	x11-libs/cairo[X]
+	x11-libs/gtk+:3[X]
+	x11-libs/pango[X]"
+
+DEPEND="${PYTHON_DEPS}
+	${RDEPEND}"
+
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	test? ( dev-util/cpputest )"
+
+src_prepare() {
+	# disable compress man pages
+	sed -i -e \
+		'/install(FILES/s|${MANFILE_FULL_GZ}|${CMAKE_SOURCE_DIR}/data/cherrytree.1|' \
+		CMakeLists.txt || die
+
+	# python_fix_shebang .
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPYTHON_EXEC="${PYTHON}"
+		-DUSE_NLS=$(usex nls)
+		-DBUILD_TESTING=$(usex test)
+		-DUSE_SHARED_FMT_SPDLOG=ON
+	)
+
+	cmake_src_configure
+}