x11-wm/dwm: add 6.5

Signed-off-by: Petr Vaněk <arkamar@gentoo.org>

1 files changed, 68 insertions, 0 deletions

diff --git a/x11-wm/dwm/dwm-6.5.ebuild b/x11-wm/dwm/dwm-6.5.ebuild
new file mode 100644
index 000000000000..5881e52a6091
--- /dev/null
+++ b/x11-wm/dwm/dwm-6.5.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit savedconfig toolchain-funcs
+
+DESCRIPTION="a dynamic window manager for X11"
+HOMEPAGE="https://dwm.suckless.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.suckless.org/dwm"
+else
+	SRC_URI="https://dl.suckless.org/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="xinerama"
+
+RDEPEND="
+	media-libs/fontconfig
+	x11-libs/libX11
+	>=x11-libs/libXft-2.3.5
+	xinerama? ( x11-libs/libXinerama )
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+	xinerama? ( x11-base/xorg-proto )
+"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "s/ -Os / /" \
+		-e "/^\(LDFLAGS\|CFLAGS\|CPPFLAGS\)/{s| = | += |g;s|-s ||g}" \
+		-e "/^X11LIB/{s:/usr/X11R6/lib:/usr/$(get_libdir)/X11:}" \
+		-e '/^X11INC/{s:/usr/X11R6/include:/usr/include/X11:}' \
+		config.mk || die
+
+	restore_config config.h
+}
+
+src_compile() {
+	if use xinerama; then
+		emake CC="$(tc-getCC)" dwm
+	else
+		emake CC="$(tc-getCC)" XINERAMAFLAGS="" XINERAMALIBS="" dwm
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+
+	exeinto /etc/X11/Sessions
+	newexe "${FILESDIR}"/dwm-session2 dwm
+
+	insinto /usr/share/xsessions
+	doins "${FILESDIR}"/dwm.desktop
+
+	dodoc README
+
+	save_config config.h
+}