www-misc/buku: bump to 4.5 (and python3.9)

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: John Helmert III <jchelmert3@posteo.net>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 87 insertions, 0 deletions

diff --git a/www-misc/buku/Manifest b/www-misc/buku/Manifest
index 3e4a4ad721de..cc0bc646868d 100644
--- a/www-misc/buku/Manifest
+++ b/www-misc/buku/Manifest
@@ -1,2 +1,3 @@
 DIST buku-4.3.tar.gz 264480 BLAKE2B 8bddf640512e5741f80bb5bc073208d843cac32d3c3ade0bdf36241e93d6c81d47238ad03c651e924226933efa572e65d9a4c86f861acda68935c9e96d6e6fb4 SHA512 eabf45b1cc1700b20f2a95baf14940f49e2a2ad51aef0f870c488e67cb07fb110916d93037830cd83572317c5d0a8b05c0a5732f105face2a14facf6af02b690
 DIST buku-4.4.tar.gz 273207 BLAKE2B bff849f03ba6b2f8779a9445da26f64875ccc6a7cb1434cba51237742a7b9968d302ee0dd9f87fd2857922660fc304d07012a962c080704d7d99312e8672e4d0 SHA512 5ccd3e72b2256d4d3daf007ffc9279c9958eec6a5baa913cb31bf97d978db227e28311f882a930da737c002ec0750ee9f8cf0f7584e639154398ba5d486bd8ba
+DIST buku-4.5.tar.gz 488913 BLAKE2B 29ed93fa9af4503f72a711889fbf17d86bcde1bc1abbfc88242c4ebd18f1c1a57077781eebdd79d9d993078d2f5b5883c9a0ec4fee94e37c0e7bfb727c5154d0 SHA512 7bbb598d5c970e8e594d58c0a18f9b85245d4a214c01d64b537a5ccaadab32c964521046b90754c2f2c721bf816dc7f4438cfeff3a7e7eec75ce958cc41dfa7d
diff --git a/www-misc/buku/buku-4.5.ebuild b/www-misc/buku/buku-4.5.ebuild
new file mode 100644
index 000000000000..105679cc5a95
--- /dev/null
+++ b/www-misc/buku/buku-4.5.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+PYTHON_REQ_USE="sqlite"
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="Powerful command-line bookmark manager"
+HOMEPAGE="https://github.com/jarun/buku"
+SRC_URI="https://github.com/jarun/${PN}/archive/v$(ver_cut 1-2).tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/beautifulsoup-4.6.0[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	>=dev-python/html5lib-1.0.1[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/attrs[${PYTHON_USEDEP}]
+		>=dev-python/click-7.0[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		>=dev-python/py-1.5.0[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-4.2[${PYTHON_USEDEP}]
+		>=dev-python/vcrpy-4.0.2[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# Remove support for bukuserver - complex depgraph which isn't all
+	# sufficiently packaged in Gentoo
+	sed -ie '/console_scripts/s/,.*/]/' setup.py || die
+	sed -ie 's/.*bukuserver.*//' tests/test_views.py || die
+	sed -ie 's/.*flask.*//' tests/test_views.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /usr/share/zsh/site-functions
+	doins auto-completion/zsh/_*
+
+	newbashcomp auto-completion/bash/buku-completion.bash "${PN}"
+
+	doman buku.1
+}
+
+python_test() {
+	local skipped_tests=(
+		# Disable tests related to bukuserver
+		tests/test_setup.py::test_bukuserver_requirement
+		tests/test_views.py::test_bmv_create_form
+		tests/test_views.py::test_bookmark_model_view
+		tests/test_views.py::test_load_firefox_database
+		tests/test_views.py::test_tag_model_view_get_list
+		tests/test_views.py::test_tag_model_view_get_list_empty_db
+
+		# Broken with network-sandbox
+		tests/test_buku.py::test_network_handler_with_url
+		tests/test_bukuDb.py::TestBukuDb::test_tnyfy_url
+		tests/test_bukuDb.py::test_add_rec_exec_arg
+		tests/test_bukuDb.py::test_load_firefox
+		tests/test_bukuDb.py::test_print_rec_hypothesis
+		tests/test_bukuDb.py::test_refreshdb
+
+		# Passes when called alone, fails when run from the suite,
+		# but only when the network is disabled
+		tests/test_bukuDb.py::test_delete_rec_index_and_delay_commit[1-True-False]
+	)
+
+	# tests/test_server.py is bukuserver tests, ignore it
+	pytest -v --ignore tests/test_server.py ${skipped_tests[@]/#/--deselect } || die "Tests failed with ${EPYTHON}"
+}