sys-libs/libnvme: revbump for Python fix

Followup to ba65982faccd363da37bc8953ee51b4475727876. parona made a fair point
that a revbump is technically warranted given that with USE=python, we may
get an additional impl installed outside of what PYTHON_TARGETS covered
(e.g. if configure picks up Python 3.12, builds & installs that, then the
proper Python impl builds do Python 3.11).

Revbump for correctness accordingly. After he said it, I realised it wasn't
just a technicality, but actually pretty plausible as well.

Bug: https://bugs.gentoo.org/923853
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 76 insertions, 0 deletions

diff --git a/sys-libs/libnvme/libnvme-1.7.1-r1.ebuild b/sys-libs/libnvme/libnvme-1.7.1-r1.ebuild
new file mode 100644
index 000000000000..5dce034744c3
--- /dev/null
+++ b/sys-libs/libnvme/libnvme-1.7.1-r1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit python-r1 meson
+
+DESCRIPTION="C Library for NVM Express on Linux"
+HOMEPAGE="https://github.com/linux-nvme/libnvme"
+SRC_URI="https://github.com/linux-nvme/libnvme/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~alpha amd64 arm arm64 ~ia64 ~loong ~mips ~ppc ppc64 ~riscv ~sparc x86"
+IUSE="dbus +json keyutils python ssl test +uuid"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="
+	python? ( ${PYTHON_REQUIRED_USE} )
+"
+
+DEPEND="
+	json? ( dev-libs/json-c:= )
+	keyutils? ( sys-apps/keyutils:= )
+	dbus? ( sys-apps/dbus:= )
+	python? ( ${PYTHON_DEPS} )
+	ssl? ( >=dev-libs/openssl-1.1:= )
+	uuid? ( sys-apps/util-linux:= )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-lang/swig
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dpython=false
+		$(meson_use test tests)
+		$(meson_feature json json-c)
+		$(meson_feature dbus libdbus)
+		$(meson_feature keyutils)
+		$(meson_feature ssl openssl)
+	)
+	meson_src_configure
+}
+
+python_compile() {
+	local emesonargs=(
+		-Dpython=enabled
+	)
+	meson_src_configure --reconfigure
+	meson_src_compile
+}
+
+src_compile() {
+	meson_src_compile
+
+	if use python; then
+		python_copy_sources
+		python_foreach_impl python_compile
+	fi
+}
+
+python_install() {
+	meson_src_install
+	use python && python_optimize
+}
+
+src_install() {
+	use python && python_foreach_impl python_install
+
+	meson_src_install
+}