sys-devel/dwz: add 9999

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 68 insertions, 8 deletions

diff --git a/sys-devel/dwz/dwz-0.15-r1.ebuild b/sys-devel/dwz/dwz-0.15-r1.ebuild
index 07e6062f11f1..6ea8c380f942 100644
--- a/sys-devel/dwz/dwz-0.15-r1.ebuild
+++ b/sys-devel/dwz/dwz-0.15-r1.ebuild
@@ -7,13 +7,18 @@ inherit toolchain-funcs
 
 DESCRIPTION="DWARF optimization and duplicate removal tool"
 HOMEPAGE="https://sourceware.org/dwz"
-SRC_URI="https://sourceware.org/ftp/dwz/releases/${P}.tar.xz"
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://sourceware.org/git/dwz.git"
+	inherit git-r3
+else
+	SRC_URI="https://sourceware.org/ftp/dwz/releases/${P}.tar.xz"
+	S="${WORKDIR}/${PN}"
 
-S="${WORKDIR}/${PN}"
+	KEYWORDS="amd64 arm arm64 ppc ppc64 ~riscv sparc x86"
+fi
 
 LICENSE="GPL-2+ GPL-3+"
 SLOT="0"
-KEYWORDS="amd64 arm arm64 ppc ppc64 ~riscv sparc x86"
 IUSE="test"
 RESTRICT="!test? ( test )"
 
@@ -22,11 +27,13 @@ RDEPEND="
 	dev-libs/xxhash
 "
 DEPEND="${RDEPEND}"
-BDEPEND="test? (
-	dev-libs/elfutils[utils]
-	dev-util/dejagnu
-	dev-debug/gdb
-)"
+BDEPEND="
+	test? (
+		dev-debug/gdb
+		dev-libs/elfutils[utils]
+		dev-util/dejagnu
+	)
+"
 
 src_prepare() {
 	default
diff --git a/sys-devel/dwz/dwz-9999.ebuild b/sys-devel/dwz/dwz-9999.ebuild
new file mode 100644
index 000000000000..8ce1dc9e912c
--- /dev/null
+++ b/sys-devel/dwz/dwz-9999.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="DWARF optimization and duplicate removal tool"
+HOMEPAGE="https://sourceware.org/dwz"
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://sourceware.org/git/dwz.git"
+	inherit git-r3
+else
+	SRC_URI="https://sourceware.org/ftp/dwz/releases/${P}.tar.xz"
+	S="${WORKDIR}/${PN}"
+
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="GPL-2+ GPL-3+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/elfutils
+	dev-libs/xxhash
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	test? (
+		dev-debug/gdb
+		dev-libs/elfutils[utils]
+		dev-util/dejagnu
+	)
+"
+
+src_prepare() {
+	default
+	tc-export CC
+}
+
+src_compile() {
+	emake CFLAGS="${CFLAGS}" srcdir="${S}"
+}
+
+src_test() {
+	emake CFLAGS="${CFLAGS}" srcdir="${S}" check
+}
+
+src_install() {
+	emake DESTDIR="${D}" CFLAGS="${CFLAGS}" srcdir="${S}" install
+}