sci-mathematics/coq-serapi: bump to 0.20.0

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

2 files changed, 84 insertions, 0 deletions

diff --git a/sci-mathematics/coq-serapi/Manifest b/sci-mathematics/coq-serapi/Manifest
index 11247d765a45..79de2ff00dfb 100644
--- a/sci-mathematics/coq-serapi/Manifest
+++ b/sci-mathematics/coq-serapi/Manifest
@@ -1 +1,2 @@
 DIST coq-serapi-0.19.0.tar.gz 180779 BLAKE2B 27083a851139e983158b4cb251d37971d0eec61dd91303a0d09512e690c56a75624dab8c5120eebaed1e7bb168d0b2b889d538854812506c4d0a804f7bee7423 SHA512 e01706beb957315011682f2f74448e66c7a8a077418eeaf7d3fa21414bdf88950b75adbfe2392656e4d6036ce6585d4d53b1dadfd8379249b2943ea389c9c83e
+DIST coq-serapi-0.20.0.tar.gz 182481 BLAKE2B 0483eb7023c67b42def13d23ceec7375d4a575f58ef0b6ed39cbcf8c8f76633c74c83bdebff18b7a777d90beeb20d03c38f20cff525afd1822db31c4a168d413 SHA512 00f8ff851c1b99f45761d098af51949f9a6844d05e23b2cede795bb4f93a9a0a753b45c38271537b257f0ec9cd7538be251174eff483a89cd57889f40a358c27
diff --git a/sci-mathematics/coq-serapi/coq-serapi-0.20.0.ebuild b/sci-mathematics/coq-serapi/coq-serapi-0.20.0.ebuild
new file mode 100644
index 000000000000..2a430ae8faf5
--- /dev/null
+++ b/sci-mathematics/coq-serapi/coq-serapi-0.20.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+COQ_MIN_V="8.20.0"
+COQ_MAX_V="8.21.0"
+
+inherit dune elisp-common
+
+DESCRIPTION="Serialization library and protocol for interaction with the Coq proof assistant"
+HOMEPAGE="https://github.com/ejgallego/coq-serapi/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/ejgallego/${PN}.git"
+else
+	# The tarball in SRC_URI is comprised of <supported coq>+<package version>
+	SRC_URI="https://github.com/ejgallego/${PN}/archive/${COQ_MIN_V}+${PV}.tar.gz
+		-> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-${COQ_MIN_V}-${PV}"
+
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0/${PV}"
+IUSE="emacs +ocamlopt test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=sci-mathematics/coq-${COQ_MIN_V}:= <sci-mathematics/coq-${COQ_MAX_V}:=
+	>=dev-ml/ppx_sexp_conv-0.13.0:=
+	dev-ml/cmdliner:=
+	dev-ml/ppx_compare:=
+	dev-ml/ppx_deriving:=
+	dev-ml/ppx_deriving_yojson:=
+	dev-ml/ppx_hash:=
+	dev-ml/ppx_import:=
+	dev-ml/sexplib:=
+	dev-ml/yojson:=
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	emacs? (
+		>=app-editors/emacs-23.1:*
+	)
+	test? (
+		sci-mathematics/coq-mathcomp
+	)
+"
+
+PATCHES=( "${FILESDIR}/${PN}-0.19.0-sertop-el.patch" )
+
+SITEFILE="50sertop-gentoo.el"
+
+src_compile() {
+	dune_src_compile
+
+	use emacs && elisp-compile sertop/*.el
+}
+
+src_install() {
+	dune_src_install
+
+	rm -r "${ED}/usr/share/emacs" || die
+
+	if use emacs ; then
+		elisp-install "${PN}" sertop/*.el{,c}
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}