net-wireless/blueman: Bump to 2.1.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 135 insertions, 0 deletions

diff --git a/net-wireless/blueman/Manifest b/net-wireless/blueman/Manifest
index 6aaa49d57d4b..e55cb5288c15 100644
--- a/net-wireless/blueman/Manifest
+++ b/net-wireless/blueman/Manifest
@@ -1 +1,2 @@
 DIST blueman-2.1.1.tar.xz 950296 BLAKE2B 10113bf9bd6744d6aaa5e4d0912d87ba11ace36027acfb10802988ad7c7458dbe2c092095148277f437a8dac68f93c017da53a0925a2c3e8c24e0400db567c87 SHA512 bde7dffc369a7204e2c0e05005f3c1cb97760b3d8625342fe69a5b5c729d6b90eabeca37c679c56f73499f1dbc17ccc15800b4e6e48e717f0e306083525981e9
+DIST blueman-2.1.2.tar.xz 950296 BLAKE2B dec19174813a76d5abb941b7a93257428175961c4f05709e5c1ba304302b4163a61cde2ae5938f40053ea43298ee8ac483cd0439c80ce76bae41a95b3dc8d5ac SHA512 44d397d3a9d154d05b5231e18e624bf1ca33c690be5eeb448620ba4882110306925b78dbbbd815384ee3faeff147d2b042c01be28fb1b43568924c9657484527
diff --git a/net-wireless/blueman/blueman-2.1.2.ebuild b/net-wireless/blueman/blueman-2.1.2.ebuild
new file mode 100644
index 000000000000..36efcd261c60
--- /dev/null
+++ b/net-wireless/blueman/blueman-2.1.2.ebuild
@@ -0,0 +1,134 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{6,7} )
+inherit autotools gnome2-utils linux-info python-single-r1 systemd xdg-utils
+
+DESCRIPTION="Simple and intuitive GTK+ Bluetooth Manager"
+HOMEPAGE="https://github.com/blueman-project/blueman"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/blueman-project/blueman.git"
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/blueman-project/${PN}/releases/download/${PV/_/.}/${P/_/.}.tar.xz"
+	S=${WORKDIR}/${P/_/.}
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+fi
+
+# icons are GPL-2
+# source files are mixed GPL-3+ and GPL-2+
+LICENSE="GPL-3+ GPL-2"
+SLOT="0"
+IUSE="appindicator network nls policykit pulseaudio"
+
+DEPEND="
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
+	')
+	>=net-wireless/bluez-5:=
+	${PYTHON_DEPS}"
+BDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/cython[${PYTHON_MULTI_USEDEP}]
+	')
+	virtual/pkgconfig
+	nls? ( dev-util/intltool sys-devel/gettext )"
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/pycairo[${PYTHON_MULTI_USEDEP}]
+	')
+	sys-apps/dbus
+	x11-libs/gtk+:3[introspection]
+	x11-libs/libnotify[introspection]
+	|| (
+		x11-themes/adwaita-icon-theme
+		x11-themes/faenza-icon-theme
+		x11-themes/mate-icon-theme
+	)
+	appindicator? ( dev-libs/libappindicator:3[introspection] )
+	network? (
+		net-firewall/iptables
+		|| (
+			sys-apps/net-tools
+			sys-apps/iproute2
+		)
+		|| (
+			net-dns/dnsmasq
+			net-misc/dhcp
+			>=net-misc/networkmanager-0.8
+		)
+	)
+	policykit? ( sys-auth/polkit )
+	pulseaudio? (
+		|| (
+			media-sound/pulseaudio[bluetooth]
+			media-sound/pulseaudio-modules-bt
+		)
+	)
+	!net-wireless/gnome-bluetooth
+"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+pkg_pretend() {
+	if use network; then
+		local CONFIG_CHECK="~BRIDGE ~IP_NF_IPTABLES
+			~IP_NF_NAT ~IP_NF_TARGET_MASQUERADE"
+		check_extra_config
+	fi
+}
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	# replace py-compile to fix py3
+	[[ ${PV} == 9999 ]] && eautoreconf || eautomake
+}
+
+src_configure() {
+	local myconf=(
+		--docdir=/usr/share/doc/${PF}
+		--disable-runtime-deps-check
+		--disable-static
+		--with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
+		--with-systemduserunitdir="$(systemd_get_userunitdir)"
+		--with-dhcp-config="/etc/dhcp/dhcpd.conf"
+		$(use_enable appindicator)
+		$(use_enable policykit polkit)
+		$(use_enable nls)
+		$(use_enable pulseaudio)
+		# thunar integration is a single data file with no extra deps
+		# so install it unconditionally
+		--enable-thunar-sendto
+	)
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	if use policykit; then
+		# Allow users in plugdev group to modify connections
+		insinto /usr/share/polkit-1/rules.d
+		doins "${FILESDIR}/01-org.blueman.rules"
+	fi
+
+	rm "${D}"/$(python_get_sitedir)/*.la || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}