net-nds/rpcbind: fix detection of rpcsvc/mount.h

Dropped ~riscv keyword due to sys-fs/quota.

Closes: https://bugs.gentoo.org/665222
Package-Manager: Portage-2.3.84_p2, Repoman-2.3.20_p24
Signed-off-by: Mike Gilbert <floppym@gentoo.org>

2 files changed, 70 insertions, 2 deletions

diff --git a/net-nds/rpcbind/rpcbind-1.2.5-r1.ebuild b/net-nds/rpcbind/rpcbind-1.2.5-r1.ebuild
new file mode 100644
index 000000000000..59bcc41863e0
--- /dev/null
+++ b/net-nds/rpcbind/rpcbind-1.2.5-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit flag-o-matic systemd
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="git://linux-nfs.org/~steved/rpcbind.git"
+	inherit autotools git-r3
+else
+	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+fi
+
+DESCRIPTION="portmap replacement which supports RPC over various protocols"
+HOMEPAGE="https://sourceforge.net/projects/rpcbind/"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="debug remotecalls selinux systemd tcpd warmstarts"
+REQUIRED_USE="systemd? ( warmstarts )"
+
+CDEPEND=">=net-libs/libtirpc-0.2.3:=
+	systemd? ( sys-apps/systemd:= )
+	tcpd? ( sys-apps/tcp-wrappers )"
+DEPEND="${CDEPEND}
+	sys-fs/quota[rpc]
+	virtual/pkgconfig"
+RDEPEND="${CDEPEND}
+	selinux? ( sec-policy/selinux-rpcbind )"
+
+src_prepare() {
+	default
+	[[ ${PV} == "9999" ]] && eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--bindir="${EPREFIX}"/sbin
+		--sbindir="${EPREFIX}"/sbin
+		--with-statedir="${EPREFIX}"/run/${PN}
+		--with-systemdsystemunitdir=$(usex systemd "$(systemd_get_systemunitdir)" "no")
+		$(use_enable debug)
+		$(use_enable remotecalls rmtcalls)
+		$(use_enable warmstarts)
+		$(use_enable tcpd libwrap)
+	)
+
+	# Allow configure to find /usr/include/rpc/rpc.h in rpcsvc/mount.h
+	# https://bugs.gentoo.org/665222
+	append-cppflags "$($(tc-getPKG_CONFIG) --cflags libtirpc)"
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+}
diff --git a/net-nds/rpcbind/rpcbind-9999.ebuild b/net-nds/rpcbind/rpcbind-9999.ebuild
index 7e3bbeae8e85..59bcc41863e0 100644
--- a/net-nds/rpcbind/rpcbind-9999.ebuild
+++ b/net-nds/rpcbind/rpcbind-9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
 
-inherit systemd
+inherit flag-o-matic systemd
 
 if [[ ${PV} == "9999" ]] ; then
 	EGIT_REPO_URI="git://linux-nfs.org/~steved/rpcbind.git"
@@ -25,6 +25,7 @@ CDEPEND=">=net-libs/libtirpc-0.2.3:=
 	systemd? ( sys-apps/systemd:= )
 	tcpd? ( sys-apps/tcp-wrappers )"
 DEPEND="${CDEPEND}
+	sys-fs/quota[rpc]
 	virtual/pkgconfig"
 RDEPEND="${CDEPEND}
 	selinux? ( sec-policy/selinux-rpcbind )"
@@ -45,6 +46,11 @@ src_configure() {
 		$(use_enable warmstarts)
 		$(use_enable tcpd libwrap)
 	)
+
+	# Allow configure to find /usr/include/rpc/rpc.h in rpcsvc/mount.h
+	# https://bugs.gentoo.org/665222
+	append-cppflags "$($(tc-getPKG_CONFIG) --cflags libtirpc)"
+
 	econf "${myeconfargs[@]}"
 }