net-misc/electrum: Bump to 4.3.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 96 insertions, 0 deletions

diff --git a/net-misc/electrum/Manifest b/net-misc/electrum/Manifest
index 56775674b3f3..2031ec8d4ea7 100644
--- a/net-misc/electrum/Manifest
+++ b/net-misc/electrum/Manifest
@@ -1 +1,2 @@
 DIST electrum-4.3.1.gh.tar.gz 5444509 BLAKE2B 68d63b730396c229bcb09262740a7d3ef322fce7fd16265d352e3eb2039e123d043307036d906b1688cc43d33620cf1b8f7aaa03ac9f5d68e5f9a2b84e6d44a7 SHA512 038b7c643ed11fe14e368be91bc09e5f043d4ae86cdf0ad0d80861ffa47aececcc4b0bec5a8596a8d78590b859bf302ed99d2d57bab1a2a053677fc7fa190e06
+DIST electrum-4.3.2.gh.tar.gz 5460546 BLAKE2B b2367116aef2a2a76dca30a635188bcd99f0fdd46ce6e8c5a2d6608fbb8f0a58e88b8352c5db92b7c8709f7bbc420fc1860204aca1efc2f2c4be2c788bfa1909 SHA512 dfb137e01ca6e511fb5ac70c34dcb01f36bdb209d7d290bd53c8fa5f95783f346898478d6e58435b241928dfe05ff46455e2e587520d47892c66b3198ab89c82
diff --git a/net-misc/electrum/electrum-4.3.2.ebuild b/net-misc/electrum/electrum-4.3.2.ebuild
new file mode 100644
index 000000000000..52e7834f1a47
--- /dev/null
+++ b/net-misc/electrum/electrum-4.3.2.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="ncurses?"
+
+inherit distutils-r1 xdg-utils
+
+DESCRIPTION="User friendly Bitcoin client"
+HOMEPAGE="
+	https://electrum.org/
+	https://github.com/spesmilo/electrum/
+"
+SRC_URI="
+	https://github.com/spesmilo/electrum/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cli ncurses qrcode +qt5"
+REQUIRED_USE="|| ( cli ncurses qt5 )"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/libsecp256k1
+	>=dev-python/aiohttp-socks-0.3[${PYTHON_USEDEP}]
+	=dev-python/aiorpcX-0.22*[${PYTHON_USEDEP}]
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	dev-python/bitstring[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	>=dev-python/dnspython-2[${PYTHON_USEDEP}]
+	dev-python/pbkdf2[${PYTHON_USEDEP}]
+	dev-python/PySocks[${PYTHON_USEDEP}]
+	dev-python/qrcode[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=dev-python/protobuf-python-3.12[${PYTHON_USEDEP}]
+	qrcode? ( media-gfx/zbar[v4l] )
+	qt5? (
+		dev-python/PyQt5[gui,widgets,${PYTHON_USEDEP}]
+	)
+	ncurses? ( $(python_gen_impl_dep 'ncurses') )
+"
+BDEPEND="
+	test? (
+		dev-python/pyaes[${PYTHON_USEDEP}]
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# use backwards-compatible cryptodome API
+	sed -i -e 's:Cryptodome:Crypto:' electrum/crypto.py || die
+
+	# make qdarkstyle dep optional
+	sed -i -e '/qdarkstyle/d' contrib/requirements/requirements.txt || die
+
+	local bestgui
+	if use qt5; then
+		bestgui=qt
+	elif use ncurses; then
+		bestgui=text
+	else
+		bestgui=stdio
+	fi
+	sed -i 's/^\([[:space:]]*\)\(config_options\['\''cwd'\''\] = .*\)$/\1\2\n\1config_options.setdefault("gui", "'"${bestgui}"'")\n/' ${PN}/${PN} || die
+
+	eapply_user
+
+	xdg_environment_reset
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	dodoc RELEASE-NOTES
+	distutils-r1_src_install
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}