net-dns/pdns-recursor: add 4.9.2

Signed-off-by: Sven Wegener <swegener@gentoo.org>

2 files changed, 92 insertions, 0 deletions

diff --git a/net-dns/pdns-recursor/Manifest b/net-dns/pdns-recursor/Manifest
index 4e8f6463ebbb..6cdc8ca1dd4c 100644
--- a/net-dns/pdns-recursor/Manifest
+++ b/net-dns/pdns-recursor/Manifest
@@ -1,2 +1,3 @@
 DIST pdns-recursor-4.9.0.tar.bz2 1551436 BLAKE2B 6e0dbaa6c666599b1d4246c544d8933d9b476b55f946c8a9d67c5983e3f2745947e3a225bd198d11566dd97a45e47022bba56f53a1a1b9b70b71b80656118f04 SHA512 c9694fe7c852441d55c9e89e7d212e7d5a3a4e81742adc5240f673f9bc91205a36a6071e5992baec078806e8ae73f390dfc0b5ed795365a35040284372f8e6ad
 DIST pdns-recursor-4.9.1.tar.bz2 1566613 BLAKE2B c5c8cc577739411b0106bf2ca26e4bca708b70c9294ac5f57086d64290a3d106dd001d06e42365efb4d448f130ce50406e5fd47a83f79c8f18236c4dbf0eff4f SHA512 f342699fad0cee9dadc6d59edb5770d1f81bac5a4cb3cf7fef0e1f15ae65ff504e95f0e9de91c36cdef40f6ab2c6a27aebdb377e1f043c4f03b82da7cbd9051b
+DIST pdns-recursor-4.9.2.tar.bz2 1562694 BLAKE2B 21d5fc0645c9cac65ec71c4e11d285b5d166d688e650911854417bf8f92bd7948a9b1f71767689ea2fe370e7bfd96ba0987e31fb28d528a09cb3711ef3aedf33 SHA512 ee2dac5d256c9f4a9155fe6885522c5413482f0fd179099e956db2abbf4510fc6696fc1ac93bb4af341ebb2f052350637524267aa21fe6a0e92194e9219d1d45
diff --git a/net-dns/pdns-recursor/pdns-recursor-4.9.2.ebuild b/net-dns/pdns-recursor/pdns-recursor-4.9.2.ebuild
new file mode 100644
index 000000000000..08de25898f64
--- /dev/null
+++ b/net-dns/pdns-recursor/pdns-recursor-4.9.2.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit flag-o-matic lua-single
+
+DESCRIPTION="The PowerDNS Recursor"
+HOMEPAGE="https://www.powerdns.com/"
+SRC_URI="https://downloads.powerdns.com/releases/${P/_/-}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="debug dnstap snmp sodium systemd test valgrind"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+DEPEND="${LUA_DEPS}
+	dnstap? ( dev-libs/fstrm )
+	systemd? ( sys-apps/systemd:0= )
+	snmp? ( net-analyzer/net-snmp )
+	sodium? ( dev-libs/libsodium:= )
+	elibc_glibc? (
+		arm? ( >=sys-libs/glibc-2.34 )
+		x86? ( >=sys-libs/glibc-2.34 )
+	)
+	dev-libs/openssl:=
+	dev-libs/boost:=[context]"
+RDEPEND="${DEPEND}
+	!<net-dns/pdns-2.9.20-r1
+	acct-user/pdns
+	acct-group/pdns"
+DEPEND="${DEPEND}
+	valgrind? ( dev-util/valgrind )"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}"/${P/_/-}
+
+pkg_setup() {
+	lua-single_pkg_setup
+	filter-flags -ftree-vectorize
+	append-lfs-flags
+	append-cppflags -D_TIME_BITS=64
+}
+
+src_configure() {
+	econf \
+		--sysconfdir=/etc/powerdns \
+		--with-nod-cache-dir=/var/lib/powerdns \
+		--with-service-user=pdns \
+		--with-service-group=pdns \
+		--with-lua="${ELUA}" \
+		$(use_enable debug verbose-logging) \
+		$(use_enable systemd) \
+		$(use_enable dnstap dnstap) \
+		$(use_enable test unit-tests) \
+		$(use_enable valgrind) \
+		$(use_with sodium libsodium) \
+		$(use_with snmp net-snmp)
+}
+
+src_install() {
+	default
+
+	mv "${D}"/etc/powerdns/recursor.conf{-dist,}
+
+	# set defaults: setuid=nobody, setgid=nobody
+	sed -i \
+		-e 's/^# set\([ug]\)id=$/set\1id=pdns/' \
+		-e 's/^# quiet=$/quiet=on/' \
+		-e 's/^# chroot=$/chroot=\/var\/lib\/powerdns/' \
+		"${D}"/etc/powerdns/recursor.conf
+
+	newinitd "${FILESDIR}"/pdns-recursor-r2 pdns-recursor
+}
+
+pkg_postinst() {
+	local old
+
+	for old in ${REPLACING_VERSIONS}; do
+		ver_test ${old} -lt 4.0.0-r1 || continue
+
+		ewarn "Starting with 4.0.0-r1 the init script has been renamed from precursor"
+		ewarn "to pdns-recursor, please update your runlevels accordingly."
+
+		break
+	done
+}