net-dns/pdns-recursor: Version bump, security bug #730362

Bug: https://bugs.gentoo.org/730362
Package-Manager: Portage-2.3.99, Repoman-2.3.23
Signed-off-by: Sven Wegener <swegener@gentoo.org>

2 files changed, 82 insertions, 0 deletions

diff --git a/net-dns/pdns-recursor/Manifest b/net-dns/pdns-recursor/Manifest
index 52c8e3e1c43b..79e1ae83ecde 100644
--- a/net-dns/pdns-recursor/Manifest
+++ b/net-dns/pdns-recursor/Manifest
@@ -1 +1,2 @@
 DIST pdns-recursor-4.3.1.tar.bz2 1334817 BLAKE2B 1972259e42b1cefd9069a36d2bb235652ce234d525a2e3f19c96a93bf26f34063e6d04240146bba0560573c1d2ad042a579d6ab557fc7ac0aadee09fa15ee397 SHA512 49ae4957ef202f94ec87e6449dfa9c147689b5576ca1002e0155319099d698300c113e221571f6d41cb1cdc1649619621c2ccf8105620c25452ac30bd83e46b8
+DIST pdns-recursor-4.3.2.tar.bz2 1354549 BLAKE2B 253f9a6ec3b7bfb4d3a97953c9f65458b479bdaa20fcc28d980a1cf4c1f15f80ad35251687bb5410f14268be79de4bbcec8bc36663a0a8eb51894fa6e4242547 SHA512 d1ca566dc8785fda3764838a0ea598acc4106b6261ebdbbe43fc6a6e4a82c375f7ef3f6d23fbd9b216067eb9cf56fcae6d460bfc7957ba4c201d466ad15d75d7
diff --git a/net-dns/pdns-recursor/pdns-recursor-4.3.2.ebuild b/net-dns/pdns-recursor/pdns-recursor-4.3.2.ebuild
new file mode 100644
index 000000000000..0806261b1f4c
--- /dev/null
+++ b/net-dns/pdns-recursor/pdns-recursor-4.3.2.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit flag-o-matic
+
+DESCRIPTION="The PowerDNS Recursor"
+HOMEPAGE="https://www.powerdns.com/"
+SRC_URI="https://downloads.powerdns.com/releases/${P/_/-}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="debug dnstap libressl luajit protobuf snmp sodium systemd"
+REQUIRED_USE="dnstap? ( protobuf )"
+
+DEPEND="!luajit? ( >=dev-lang/lua-5.1:= )
+	luajit? ( dev-lang/luajit:= )
+	protobuf? (
+		dev-libs/protobuf
+		>=dev-libs/boost-1.42:=
+	)
+	dnstap? ( dev-libs/fstrm )
+	systemd? ( sys-apps/systemd:0= )
+	snmp? ( net-analyzer/net-snmp )
+	sodium? ( dev-libs/libsodium:= )
+	libressl? ( dev-libs/libressl:= )
+	!libressl? ( dev-libs/openssl:= )
+	>=dev-libs/boost-1.35:="
+RDEPEND="${DEPEND}
+	!<net-dns/pdns-2.9.20-r1
+	acct-user/pdns
+	acct-group/pdns"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}"/${P/_/-}
+
+pkg_setup() {
+	filter-flags -ftree-vectorize
+}
+
+src_configure() {
+	econf \
+		--sysconfdir=/etc/powerdns \
+		--with-lua=$(usex luajit luajit lua) \
+		$(use_enable debug verbose-logging) \
+		$(use_enable systemd) \
+		$(use_enable dnstap dnstap) \
+		$(use_with sodium libsodium) \
+		$(use_with protobuf) \
+		$(use_with snmp net-snmp)
+}
+
+src_install() {
+	default
+
+	mv "${D}"/etc/powerdns/recursor.conf{-dist,}
+
+	# set defaults: setuid=nobody, setgid=nobody
+	sed -i \
+		-e 's/^# set\([ug]\)id=$/set\1id=pdns/' \
+		-e 's/^# quiet=$/quiet=on/' \
+		-e 's/^# chroot=$/chroot=\/var\/lib\/powerdns/' \
+		"${D}"/etc/powerdns/recursor.conf
+
+	newinitd "${FILESDIR}"/pdns-recursor-r2 pdns-recursor
+}
+
+pkg_postinst() {
+	local old
+
+	for old in ${REPLACING_VERSIONS}; do
+		ver_test ${old} -lt 4.0.0-r1 || continue
+
+		ewarn "Starting with 4.0.0-r1 the init script has been renamed from precursor"
+		ewarn "to pdns-recursor, please update your runlevels accordingly."
+
+		break
+	done
+}