media-video/mkvtoolnix: version bump to 29.0.0

Closes: https://bugs.gentoo.org/661680
Closes: https://bugs.gentoo.org/661682

Signed-off-by: Tim Harder <radhermit@gentoo.org>

3 files changed, 152 insertions, 16 deletions

diff --git a/media-video/mkvtoolnix/Manifest b/media-video/mkvtoolnix/Manifest
index 92a64993650f..44fa33eacc61 100644
--- a/media-video/mkvtoolnix/Manifest
+++ b/media-video/mkvtoolnix/Manifest
@@ -2,3 +2,4 @@ DIST mkvtoolnix-19.0.0.tar.xz 4616780 BLAKE2B 72eb3b1a34bbed0d492098c02c1f60c7ce
 DIST mkvtoolnix-21.0.0.tar.xz 4682788 BLAKE2B 52d9920fc5b735f7d8af1f6e60828f143a914ce7cd7c635daacb6d2da584b0158f80e0f4d39824130b0c8fcc83b7c3a1215b2e965cb8b47b2b297df2d78414d5 SHA512 881e0c38eee2d36ab9dea5ccaa8ad74e0076cdc13606f873ab58bfeeec09c05e947529d3bad665b1d4df6a816faca30e8a685bc19115f90c18dac3c1ae27c252
 DIST mkvtoolnix-22.0.0.tar.xz 4714712 BLAKE2B 325a0a250db8c6c833b01e6bb613044ca21b4061cbbd516ee6c60388b17c9c3759cf9759af0e2c23091d8044fd86358122e0739bf7d6133be9befca37c6d0294 SHA512 59d299f21d484dc529dafe81a35d3351e4f57abf6a2d8889692d95b9b9ffacdca9b55a3cf373b147f3ff12595590bf98f49af5d22d311b9b2d03f12a4bba00a6
 DIST mkvtoolnix-23.0.0.tar.xz 4729056 BLAKE2B a264b482f141de502fb4c4aadcdc0ec1ed4e34d2ddc906d8d1f6a0b1ea76511a590ab9d90e035955aa138512877848752185012b8e7e1aeed3007c186c796190 SHA512 3c9072b54a4076e6fb934d40a2c2554dfa1316de1cb8d74ab262b0584eda1e679324aaf690195f68590413f9d3ca34d5d2a1f9f5545de065fe2db892eee19ffb
+DIST mkvtoolnix-29.0.0.tar.xz 7051380 BLAKE2B 8f5694abdbeb95c13e3a97740e3e81c02f1408116f1bdf96e8199bba0408e03278cac0bee0506b4b0aedc0a0417d61e13f31af716942faa9dbe61d16eb1d0761 SHA512 bfb5e31fdd43dbb1c3a54a9b82af414abd43f8edad1cc87e5118f8c1781185470152163fda828303c58db97df27c8037b7fa64e2077c69e3204d5080f0248dae
diff --git a/media-video/mkvtoolnix/mkvtoolnix-29.0.0.ebuild b/media-video/mkvtoolnix/mkvtoolnix-29.0.0.ebuild
new file mode 100644
index 000000000000..865f816c46ce
--- /dev/null
+++ b/media-video/mkvtoolnix/mkvtoolnix-29.0.0.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit toolchain-funcs versionator multiprocessing xdg-utils qmake-utils gnome2-utils
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://gitlab.com/mbunkus/mkvtoolnix.git"
+	inherit git-r3
+else
+	SRC_URI="https://mkvtoolnix.download/sources/${P}.tar.xz"
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+fi
+
+DESCRIPTION="Tools to create, alter, and inspect Matroska files"
+HOMEPAGE="https://mkvtoolnix.download/ https://gitlab.com/mbunkus/mkvtoolnix"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="debug nls pch test qt5"
+
+# check NEWS.md for build system changes entries for boost/libebml/libmatroska
+# version requirement updates and other packaging info
+# TODO: package fmt (http://fmtlib.net/)
+RDEPEND="
+	>=dev-libs/boost-1.49.0:=
+	>=dev-libs/libebml-1.3.5:=
+	dev-libs/jsoncpp:=
+	dev-libs/pugixml
+	media-libs/flac
+	>=media-libs/libmatroska-1.4.8:=
+	media-libs/libogg
+	media-libs/libvorbis
+	sys-apps/file
+	sys-libs/zlib
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtconcurrent:5
+		dev-qt/qtmultimedia:5
+		app-text/cmark
+	)
+"
+DEPEND="${RDEPEND}
+	dev-ruby/rake
+	virtual/pkgconfig
+	dev-libs/libxslt
+	app-text/docbook-xsl-stylesheets
+	nls? (
+		sys-devel/gettext
+		app-text/po4a
+	)
+	test? ( dev-cpp/gtest )
+"
+
+DOCS="AUTHORS NEWS.md README.md"
+
+pkg_pretend() {
+	# https://bugs.gentoo.org/419257
+	local ver=4.6
+	local msg="You need at least GCC ${ver}.x for C++11 range-based 'for' and nullptr support."
+	if ! version_is_at_least ${ver} $(gcc-version); then
+		eerror ${msg}
+		die ${msg}
+	fi
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == "9999" ]] && { ./autogen.sh || die; }
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable debug)
+		$(usex pch "" --disable-precompiled-headers)
+		$(use_enable qt5 qt)
+		$(use_with nls gettext)
+		$(usex nls "" --with-po4a-translate=false)
+		--disable-update-check
+		--disable-optimization
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		--with-boost="${EPREFIX}"/usr
+		--with-boost-libdir="${EPREFIX}"/usr/$(get_libdir)
+	)
+
+	if use qt5 ; then
+		# ac/qt5.m4 finds default Qt version set by qtchooser, bug #532600
+		myeconfargs+=(
+			--with-moc=$(qt5_get_bindir)/moc
+			--with-uic=$(qt5_get_bindir)/uic
+			--with-rcc=$(qt5_get_bindir)/rcc
+			--with-qmake=$(qt5_get_bindir)/qmake
+		)
+	fi
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	rake V=1 -j$(makeopts_jobs) || die
+}
+
+src_test() {
+	rake V=1 -j$(makeopts_jobs) tests:unit || die
+	rake V=1 -j$(makeopts_jobs) tests:run_unit || die
+}
+
+src_install() {
+	DESTDIR="${D}" rake -j$(makeopts_jobs) install || die
+
+	einstalldocs
+	doman doc/man/*.1
+}
+
+pkg_postrm() {
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postinst() {
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+	gnome2_icon_cache_update
+}
diff --git a/media-video/mkvtoolnix/mkvtoolnix-9999.ebuild b/media-video/mkvtoolnix/mkvtoolnix-9999.ebuild
index cc20f8c7ff38..865f816c46ce 100644
--- a/media-video/mkvtoolnix/mkvtoolnix-9999.ebuild
+++ b/media-video/mkvtoolnix/mkvtoolnix-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -17,10 +17,11 @@ HOMEPAGE="https://mkvtoolnix.download/ https://gitlab.com/mbunkus/mkvtoolnix"
 
 LICENSE="GPL-2"
 SLOT="0"
-IUSE="debug pch test qt5"
+IUSE="debug nls pch test qt5"
 
 # check NEWS.md for build system changes entries for boost/libebml/libmatroska
 # version requirement updates and other packaging info
+# TODO: package fmt (http://fmtlib.net/)
 RDEPEND="
 	>=dev-libs/boost-1.49.0:=
 	>=dev-libs/libebml-1.3.5:=
@@ -34,6 +35,7 @@ RDEPEND="
 	sys-libs/zlib
 	qt5? (
 		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
 		dev-qt/qtgui:5
 		dev-qt/qtnetwork:5
 		dev-qt/qtwidgets:5
@@ -44,11 +46,13 @@ RDEPEND="
 "
 DEPEND="${RDEPEND}
 	dev-ruby/rake
-	sys-devel/gettext
 	virtual/pkgconfig
 	dev-libs/libxslt
 	app-text/docbook-xsl-stylesheets
-	app-text/po4a
+	nls? (
+		sys-devel/gettext
+		app-text/po4a
+	)
 	test? ( dev-cpp/gtest )
 "
 
@@ -70,11 +74,22 @@ src_prepare() {
 }
 
 src_configure() {
-	local myconf
+	local myeconfargs=(
+		$(use_enable debug)
+		$(usex pch "" --disable-precompiled-headers)
+		$(use_enable qt5 qt)
+		$(use_with nls gettext)
+		$(usex nls "" --with-po4a-translate=false)
+		--disable-update-check
+		--disable-optimization
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		--with-boost="${EPREFIX}"/usr
+		--with-boost-libdir="${EPREFIX}"/usr/$(get_libdir)
+	)
 
 	if use qt5 ; then
 		# ac/qt5.m4 finds default Qt version set by qtchooser, bug #532600
-		myconf+=(
+		myeconfargs+=(
 			--with-moc=$(qt5_get_bindir)/moc
 			--with-uic=$(qt5_get_bindir)/uic
 			--with-rcc=$(qt5_get_bindir)/rcc
@@ -82,16 +97,7 @@ src_configure() {
 		)
 	fi
 
-	econf \
-		$(use_enable debug) \
-		$(use_enable qt5 qt) \
-		$(usex pch "" --disable-precompiled-headers) \
-		"${myconf[@]}" \
-		--disable-update-check \
-		--disable-optimization \
-		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
-		--with-boost="${EPREFIX}"/usr \
-		--with-boost-libdir="${EPREFIX}"/usr/$(get_libdir)
+	econf "${myeconfargs[@]}"
 }
 
 src_compile() {