proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

5 files changed, 163 insertions, 0 deletions

diff --git a/media-video/arista/Manifest b/media-video/arista/Manifest
new file mode 100644
index 000000000000..c6e740d1c07a
--- /dev/null
+++ b/media-video/arista/Manifest
@@ -0,0 +1,2 @@
+DIST arista-0.9.5.tar.gz 307390 SHA256 2d9b7d664225c9f4f9e2d7c365d40ed4673f87a673373cfb5612e4abe6285bd7 SHA512 c0cdd87117c7fab253997cb64854ae6b58f20c45b9f41440b9af33e729d3586e21480e177c983312ae42ff775ea3755785345c8cdb95a3b45642231c977a159c WHIRLPOOL ee5ab666b545edc0143ab780b7038b9edde8d82ee34ddcb191bbf09b12df98452b01471a282cc5712891dc07fdefae4dfdc695bb5383506e2a6ba9173c46b11b
+DIST arista-0.9.7.tar.gz 344475 SHA256 e6028e45516f0c5a736d6ec3c19f783e0a06d103cf2a816b8cc967ab964023ff SHA512 0a099f33ff56b67984485bda6a778e07c8f7ee215060b709dad22aaf70ca6489d031100d65323fa05067dfc190a8f03f884f297e62d89bc91ab36a970849df51 WHIRLPOOL 617f24e34bc62d7d43b057ea0346032ef3c13c8cc9e08b1e2705a5284967631c3cf5dc61d44aa438bb2f072baa63ffd6151e46aee2e3c0233e373e84957ec750
diff --git a/media-video/arista/arista-0.9.5.ebuild b/media-video/arista/arista-0.9.5.ebuild
new file mode 100644
index 000000000000..3fec4475d03e
--- /dev/null
+++ b/media-video/arista/arista-0.9.5.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="3"
+PYTHON_DEPEND="2"
+PYTHON_USE_WITH="xml"
+
+inherit distutils
+
+DESCRIPTION="An easy to use multimedia transcoder for the GNOME Desktop"
+HOMEPAGE="http://www.transcoder.org"
+SRC_URI="http://programmer-art.org/media/releases/arista-transcoder/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="amd64 x86"
+# Making these USE-defaults since encoding for portable devices is a very
+# common use case for Arista. xvid is being added since it's required for
+# DVD ripping. No gst-plugins-x264 available at this time.
+IUSE="+faac kde nautilus +x264 +xvid"
+
+DEPEND="dev-python/setuptools"
+RDEPEND=">=x11-libs/gtk+-2.16:2
+	|| ( dev-lang/python:2.7 dev-lang/python:2.6 dev-python/simplejson )
+	>=dev-python/pygtk-2.16:2
+	dev-python/pygobject:2
+	dev-python/pycairo
+	dev-python/gconf-python:2
+	dev-python/dbus-python
+	dev-python/python-gudev
+	gnome-base/librsvg
+	>=media-libs/gstreamer-0.10.22:0.10
+	dev-python/gst-python:0.10
+	media-libs/gst-plugins-base:0.10
+	media-libs/gst-plugins-good:0.10
+	media-libs/gst-plugins-bad:0.10
+	media-plugins/gst-plugins-meta:0.10
+	media-plugins/gst-plugins-ffmpeg:0.10
+	x11-themes/gnome-icon-theme
+	nautilus? ( dev-python/nautilus-python )
+	kde? ( dev-python/librsvg-python )
+	faac? ( media-plugins/gst-plugins-faac:0.10 )
+	x264? ( media-plugins/gst-plugins-x264:0.10 )
+	xvid? ( media-plugins/gst-plugins-xvid:0.10 )"
+
+pkg_setup() {
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+pkg_postinst() {
+	distutils_pkg_postinst
+
+	einfo "If you find that a format you want is not supported in Arista,"
+	einfo "please make sure that you have the corresponding USE-flag enabled"
+	einfo "media-plugins/gst-plugins-meta"
+}
diff --git a/media-video/arista/arista-0.9.7.ebuild b/media-video/arista/arista-0.9.7.ebuild
new file mode 100644
index 000000000000..7dd16e8b880e
--- /dev/null
+++ b/media-video/arista/arista-0.9.7.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="xml"
+
+# hack for avoiding detecting 'templates' as a locale, next part of it - in src_prepare
+PLOCALES_1="ar ast bg ca cs da de el en_GB es et eu fi fr gl hu ia id it ja jv kn lt nl pl pt pt_BR ro ru sk sl sr sv"
+PLOCALES_2="th tr uk zh_CN zh_TW"
+PLOCALES="${PLOCALES_1} ${PLOCALES_2}"
+
+inherit distutils-r1 l10n
+
+DESCRIPTION="An easy to use multimedia transcoder for the GNOME Desktop"
+HOMEPAGE="http://www.transcoder.org"
+SRC_URI="http://programmer-art.org/media/releases/arista-transcoder/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+# Making these USE-defaults since encoding for portable devices is a very
+# common use case for Arista. xvid is being added since it's required for
+# DVD ripping. No gst-plugins-x264 available at this time.
+IUSE="+faac kde nautilus +x264 +xvid"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+RDEPEND=">=x11-libs/gtk+-2.16:2
+	>=dev-python/pygtk-2.16:2[${PYTHON_USEDEP}]
+	dev-python/pygobject:2[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/gconf-python:2
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/python-gudev[${PYTHON_USEDEP}]
+	gnome-base/librsvg
+	>=media-libs/gstreamer-0.10.22:0.10
+	dev-python/gst-python:0.10[${PYTHON_USEDEP}]
+	media-libs/gst-plugins-base:0.10
+	media-libs/gst-plugins-good:0.10
+	media-libs/gst-plugins-bad:0.10
+	media-plugins/gst-plugins-meta:0.10
+	media-plugins/gst-plugins-ffmpeg:0.10
+	x11-themes/gnome-icon-theme
+	nautilus? ( dev-python/nautilus-python[${PYTHON_USEDEP}] )
+	kde? ( dev-python/librsvg-python[${PYTHON_USEDEP}] )
+	faac? ( media-plugins/gst-plugins-faac:0.10 )
+	x264? ( media-plugins/gst-plugins-x264:0.10 )
+	xvid? ( media-plugins/gst-plugins-xvid:0.10 )"
+
+PATCHES=( "${FILESDIR}/${P}-doc-install.patch" )
+
+src_prepare() {
+	# dirty hack for new locale detection
+	local PLOCALES="${PLOCALES_1} templates ${PLOCALES_2}"
+	l10n_find_plocales_changes "${S}/locale" "" ""
+
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	remove_unused_locale() {
+		rm -r "${ED}/usr/share/locale/${1}" || die "can not remove unused locale '${1}'"
+	}
+
+	distutils-r1_src_install
+
+	l10n_for_each_disabled_locale_do remove_unused_locale
+}
+
+pkg_postinst() {
+	einfo "If you find that a format you want is not supported in Arista,"
+	einfo "please make sure that you have the corresponding USE-flag enabled"
+	einfo "media-plugins/gst-plugins-meta"
+}
diff --git a/media-video/arista/files/arista-0.9.7-doc-install.patch b/media-video/arista/files/arista-0.9.7-doc-install.patch
new file mode 100644
index 000000000000..9a59c495c403
--- /dev/null
+++ b/media-video/arista/files/arista-0.9.7-doc-install.patch
@@ -0,0 +1,14 @@
+We prefer to install doc files manually through ebuild
+
+--- setup.py.orig	2013-02-12 00:35:31.387656978 +0400
++++ setup.py	2013-02-12 00:35:38.418657537 +0400
+@@ -22,9 +22,6 @@
+ 
+ data_files = [
+     (os.path.join("share", "applications"), ["arista.desktop"]),
+-    (os.path.join("share", "doc", "arista"), [
+-        "README.md", "LICENSE", "AUTHORS"
+-    ]),
+     (os.path.join("share", "nautilus-python", "extensions"), ["arista-nautilus.py"]),
+ ]
+ 
diff --git a/media-video/arista/metadata.xml b/media-video/arista/metadata.xml
new file mode 100644
index 000000000000..b8c8bd511da5
--- /dev/null
+++ b/media-video/arista/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer>
+    <email>maintainer-needed@gentoo.org</email>
+  </maintainer>
+  <use>
+	<flag name="faac">Use external faac library for AAC encoding</flag>
+	<flag name="nautilus">Add an entry in the Nautilus context menu to transcode
+		media files for a specified device.</flag>
+  </use>
+</pkgmetadata>
+