media-libs/gst-plugins-bad: bump to 1.14.5 for upstream bug fixes

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 92 insertions, 0 deletions

diff --git a/media-libs/gst-plugins-bad/Manifest b/media-libs/gst-plugins-bad/Manifest
index 9fd3b6a7d640..b4e19d1a028f 100644
--- a/media-libs/gst-plugins-bad/Manifest
+++ b/media-libs/gst-plugins-bad/Manifest
@@ -1 +1,2 @@
 DIST gst-plugins-bad-1.14.3.tar.xz 4678316 BLAKE2B b37d90e04a6bdb01e4f512df67e00790979e4b71fa6730092b4c16dbaf005cf94e09a454ed6e962faa3aaef02c2b811ad1899c3c8153b4ab3bf6d9b5f62998cf SHA512 3e92b33b43181d76bf206496c2fe0f84042c486f854f4fdba7efedc3489874944cef00eb2fd9fd7056d749be17c2b237caffc32800d7063615b30bac7226fbb7
+DIST gst-plugins-bad-1.14.5.tar.xz 4686916 BLAKE2B b22377fbadf54828e86cc4e0bb17fb9b25efe4394c64eeceb228084e58d0db595622670c6c0a2d87fb760fce34974f9e425a2b810460465130ce1a4c2c679e7d SHA512 64d2a9f6203fbeb3db19816f936f4db32dd8bb7d1f4ce1f958ae795f008e72946e8e2e8bcf8c456c33d5567cb66dc34ca95836c52e404835300a3a5f38d52b6b
diff --git a/media-libs/gst-plugins-bad/gst-plugins-bad-1.14.5.ebuild b/media-libs/gst-plugins-bad/gst-plugins-bad-1.14.5.ebuild
new file mode 100644
index 000000000000..1c39a3a7fbd8
--- /dev/null
+++ b/media-libs/gst-plugins-bad/gst-plugins-bad-1.14.5.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GST_ORG_MODULE="gst-plugins-bad"
+
+inherit flag-o-matic gstreamer virtualx
+
+DESCRIPTION="Less plugins for GStreamer"
+HOMEPAGE="https://gstreamer.freedesktop.org/"
+
+LICENSE="LGPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+
+# TODO: egl and gtk IUSE only for transition
+IUSE="X bzip2 +egl gles2 gtk +introspection +opengl +orc vcd vnc wayland" # Keep default IUSE mirrored with gst-plugins-base where relevant
+
+# X11 is automagic for now, upstream #709530 - only used by librfb USE=vnc plugin
+# We mirror opengl/gles2 from -base to ensure no automagic openglmixers plugin (with "opengl?" it'd still get built with USE=-opengl here)
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-${PV}:${SLOT}[${MULTILIB_USEDEP},introspection?]
+	>=media-libs/gst-plugins-base-${PV}:${SLOT}[${MULTILIB_USEDEP},egl?,introspection?,gles2=,opengl=]
+	introspection? ( >=dev-libs/gobject-introspection-1.31.1:= )
+
+	bzip2? ( >=app-arch/bzip2-1.0.6-r4[${MULTILIB_USEDEP}] )
+	vnc? ( X? ( x11-libs/libX11[${MULTILIB_USEDEP}] ) )
+	wayland? (
+		>=dev-libs/wayland-1.4.0[${MULTILIB_USEDEP}]
+		>=x11-libs/libdrm-2.4.55[${MULTILIB_USEDEP}]
+		>=dev-libs/wayland-protocols-1.4
+	)
+
+	gtk? ( >=media-plugins/gst-plugins-gtk-${PV}:${SLOT}[${MULTILIB_USEDEP}] )
+	orc? ( >=dev-lang/orc-0.4.17[${MULTILIB_USEDEP}] )
+"
+
+DEPEND="${RDEPEND}
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1.12
+"
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+	addpredict /dev # Prevent sandbox violations bug #570624
+}
+
+multilib_src_configure() {
+	local myconf=()
+	if use opengl || use gles2; then
+		myconf+=( --enable-gl )
+	else
+		myconf+=( --disable-gl )
+	fi
+
+	# Always enable shm (shm_open) and ipcpipeline (sys/socket.h); no extra deps
+	gstreamer_multilib_src_configure \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable bzip2 bz2) \
+		$(use_enable orc) \
+		$(use_enable vcd) \
+		$(use_enable vnc librfb) \
+		$(use_enable wayland) \
+		--disable-examples \
+		--disable-debug \
+		--without-player-tests \
+		--enable-shm \
+		--enable-ipcpipeline \
+		"${myconf[@]}"
+
+	if multilib_is_native_abi; then
+		local x
+		for x in libs plugins; do
+			ln -s "${S}"/docs/${x}/html docs/${x}/html || die
+		done
+	fi
+}
+
+multilib_src_test() {
+	unset DISPLAY
+	# Tests are slower than upstream expects
+	virtx emake check CK_DEFAULT_TIMEOUT=300
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS ChangeLog NEWS README RELEASE"
+	einstalldocs
+	find "${ED}" -name '*.la' -delete || die
+}