gnome-extra/evolution-data-server: remove old

Package-Manager: Portage-2.3.4, Repoman-2.3.1

1 files changed, 0 insertions, 128 deletions

diff --git a/gnome-extra/evolution-data-server/evolution-data-server-3.22.6.ebuild b/gnome-extra/evolution-data-server/evolution-data-server-3.22.6.ebuild
deleted file mode 100644
index 3908358bd6f6..000000000000
--- a/gnome-extra/evolution-data-server/evolution-data-server-3.22.6.ebuild
+++ /dev/null
@@ -1,128 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-GNOME2_LA_PUNT="yes"
-PYTHON_COMPAT=( python2_7 python3_{4,5} pypy )
-VALA_USE_DEPEND="vapigen"
-
-inherit db-use flag-o-matic gnome2 python-any-r1 systemd vala virtualx
-
-DESCRIPTION="Evolution groupware backend"
-HOMEPAGE="https://wiki.gnome.org/Apps/Evolution"
-
-# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
-LICENSE="|| ( LGPL-2 LGPL-3 ) BSD Sleepycat"
-SLOT="0/59" # subslot = libcamel-1.2 soname version
-
-IUSE="api-doc-extras berkdb +gnome-online-accounts +gtk google +introspection ipv6 ldap kerberos vala +weather"
-REQUIRED_USE="vala? ( introspection )"
-
-KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
-
-# sys-libs/db is only required for migrating from <3.13 versions
-# gdata-0.15.1 is required for google tasks
-# gdata-0.17.7 soft required for new gdata_feed_get_next_page_token API to handle more than 100 google tasks
-# berkdb needed only for migrating old calendar data, bug #519512
-RDEPEND="
-	>=app-crypt/gcr-3.4
-	>=app-crypt/libsecret-0.5[crypt]
-	>=dev-db/sqlite-3.7.17:=
-	>=dev-libs/glib-2.46:2
-	>=dev-libs/libgdata-0.10:=
-	>=dev-libs/libical-0.43:=
-	>=dev-libs/libxml2-2
-	>=dev-libs/nspr-4.4:=
-	>=dev-libs/nss-3.9:=
-	>=net-libs/libsoup-2.42:2.4
-
-	dev-libs/icu:=
-	sys-libs/zlib:=
-	virtual/libiconv
-
-	berkdb? ( >=sys-libs/db-4:= )
-	gtk? (
-		>=app-crypt/gcr-3.4[gtk]
-		>=x11-libs/gtk+-3.10:3
-	)
-	google? (
-		>=dev-libs/json-glib-1.0.4
-		>=dev-libs/libgdata-0.17.7:=
-		>=net-libs/webkit-gtk-2.11.91:4
-	)
-	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.8:= )
-	introspection? ( >=dev-libs/gobject-introspection-0.9.12:= )
-	kerberos? ( virtual/krb5:= )
-	ldap? ( >=net-nds/openldap-2:= )
-	weather? ( >=dev-libs/libgweather-3.10:2= )
-"
-DEPEND="${RDEPEND}
-	${PYTHON_DEPS}
-	dev-util/gdbus-codegen
-	dev-util/gperf
-	>=dev-util/gtk-doc-am-1.14
-	>=dev-util/intltool-0.35.5
-	>=gnome-base/gnome-common-2
-	>=sys-devel/gettext-0.17
-	virtual/pkgconfig
-	vala? ( $(vala_depend) )
-"
-
-# Some tests fail due to missings locales.
-# Also, dbus tests are flacky, bugs #397975 #501834
-# It looks like a nightmare to disable those for now.
-RESTRICT="test"
-
-pkg_setup() {
-	python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	use vala && vala_src_prepare
-	gnome2_src_prepare
-}
-
-src_configure() {
-	# /usr/include/db.h is always db-1 on FreeBSD
-	# so include the right dir in CPPFLAGS
-	use berkdb && append-cppflags "-I$(db_includedir)"
-
-	# phonenumber does not exist in tree
-	gnome2_src_configure \
-		$(use_enable api-doc-extras gtk-doc) \
-		$(use_with api-doc-extras private-docs) \
-		$(usex berkdb --with-libdb="${EPREFIX}"/usr --with-libdb=no) \
-		$(use_enable gnome-online-accounts goa) \
-		$(use_enable gtk) \
-		$(use_enable google google-auth) \
-		$(use_enable google) \
-		$(use_enable introspection) \
-		$(use_enable ipv6) \
-		$(use_with kerberos krb5 "${EPREFIX}"/usr) \
-		$(use_with kerberos krb5-libs "${EPREFIX}"/usr/$(get_libdir)) \
-		$(use_with ldap openldap) \
-		$(use_enable vala vala-bindings) \
-		$(use_enable weather) \
-		--enable-largefile \
-		--enable-smime \
-		--with-systemduserunitdir="$(systemd_get_userunitdir)" \
-		--without-phonenumber \
-		--disable-examples \
-		--disable-uoa
-}
-
-src_test() {
-	unset ORBIT_SOCKETDIR
-	unset SESSION_MANAGER
-	virtx emake check
-}
-
-src_install() {
-	gnome2_src_install
-
-	if use ldap; then
-		insinto /etc/openldap/schema
-		doins "${FILESDIR}"/calentry.schema
-		dosym /usr/share/${PN}/evolutionperson.schema /etc/openldap/schema/evolutionperson.schema
-	fi
-}