gnome-base/gnome-desktop: Version bump to 42.3

* Drop IUSE=introspection from -r400 (bug #856649)

Closes: https://bugs.gentoo.org/856649
Signed-off-by: Matt Turner <mattst88@gentoo.org>

3 files changed, 149 insertions, 0 deletions

diff --git a/gnome-base/gnome-desktop/Manifest b/gnome-base/gnome-desktop/Manifest
index 61cde892be64..b90007a49ea1 100644
--- a/gnome-base/gnome-desktop/Manifest
+++ b/gnome-base/gnome-desktop/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-desktop-42.1.tar.xz 743032 BLAKE2B 1eda3138e50b0ded50ede12179311ab8888ab0837c650f3e6bad600a4327cdba02b3fbf7cf7ff845669075cbb56b69ca600b8b63b4f05dce93b0a71e76cedbd7 SHA512 a084f705aedf2d159da91dc54f38261760a50e51041321e6a69ee0dff499e11f0a440f5a9582a31977b0270c87e3ba7de0f5c9cc182c0631858afa1d9508ecf4
 DIST gnome-desktop-42.2.tar.xz 743268 BLAKE2B 8f8ee5ada3bf8b11f9bd6ddfa9925d50ccc22bb3b02f4cd8caefefe76b162347dbddb5de0d6200768e0bcaf6b60c6c774155dfc3767a827c575c48ddc40380a3 SHA512 6c7d90b539b80e45f729a14dd8bf553abb09f20d16e1a2cda751b81f1e2a52e2dcb98551faab3cd4ad17206300f45c9bc968d160fddab0b71a4933f0adc22e0e
+DIST gnome-desktop-42.3.tar.xz 743196 BLAKE2B bd2c8fc49bec5b40f48f5f85311a1566fd996b2f330dcd8d3b00c2331f4800ec58b7d0281be79d29e859c8731664c6953a9ee27af92ee091d621964ac4eb51b0 SHA512 aa8e492fc09bc409619747ad53dbfd13b80251dc849db9a82fcf15c2373582af9a89f769302c8ae12330580f4a7d068f22f7fce4c42983e7848acbcd9be09d15
diff --git a/gnome-base/gnome-desktop/gnome-desktop-42.3-r300.ebuild b/gnome-base/gnome-desktop/gnome-desktop-42.3-r300.ebuild
new file mode 100644
index 000000000000..1c3c7ed2fd59
--- /dev/null
+++ b/gnome-base/gnome-desktop/gnome-desktop-42.3-r300.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome.org meson xdg
+
+DESCRIPTION="Library with common API for various GNOME modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-desktop/"
+
+LICENSE="GPL-2+ LGPL-2+ FDL-1.1+"
+SLOT="3/19" # subslot = libgnome-desktop-3 soname version
+IUSE="debug +introspection seccomp systemd udev"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+COMMON_DEPEND="
+	>=x11-libs/gdk-pixbuf-2.36.5:2[introspection?]
+	>=x11-libs/gtk+-3.3.6:3[introspection?]
+	>=dev-libs/glib-2.53.0:2
+	>=gnome-base/gsettings-desktop-schemas-3.27.0[introspection?]
+	x11-misc/xkeyboard-config
+	x11-libs/libxkbcommon
+	app-text/iso-codes
+	systemd? ( sys-apps/systemd:= )
+	udev? ( virtual/libudev:= )
+	seccomp? ( sys-libs/libseccomp )
+
+	x11-libs/cairo:=
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${COMMON_DEPEND}
+	media-libs/fontconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	seccomp? ( sys-apps/bubblewrap )
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/42.0-meson-Add-optionality-for-introspection.patch
+)
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	# Don't build manual test programs that will never get run
+	sed -i -e "/'test-.*'/d" libgnome-desktop/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dgnome_distributor=Gentoo
+		-Ddate_in_gnome_version=true
+		-Ddesktop_docs=false
+		$(meson_use debug debug_tools)
+		$(meson_use introspection)
+		$(meson_feature udev)
+		$(meson_feature systemd)
+		-Dgtk_doc=false
+		-Dinstalled_tests=false
+		-Dbuild_gtk4=false
+		-Dlegacy_library=true
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	rm -r \
+		${ED}/usr/share/gnome/gnome-version.xml \
+		${ED}/usr/share/locale \
+		|| die
+}
diff --git a/gnome-base/gnome-desktop/gnome-desktop-42.3-r400.ebuild b/gnome-base/gnome-desktop/gnome-desktop-42.3-r400.ebuild
new file mode 100644
index 000000000000..f3695ba6935e
--- /dev/null
+++ b/gnome-base/gnome-desktop/gnome-desktop-42.3-r400.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome.org meson xdg
+
+DESCRIPTION="Library with common API for various GNOME modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-desktop/"
+
+LICENSE="GPL-2+ LGPL-2+ FDL-1.1+"
+SLOT="4/1" # subslot = libgnome-desktop-4 soname version
+IUSE="debug gtk-doc seccomp systemd udev"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+COMMON_DEPEND="
+	>=x11-libs/gdk-pixbuf-2.36.5:2[introspection]
+	>=gui-libs/gtk-4.4.0:4[introspection]
+	>=dev-libs/glib-2.53.0:2
+	>=gnome-base/gsettings-desktop-schemas-3.27.0[introspection]
+	x11-misc/xkeyboard-config
+	x11-libs/libxkbcommon
+	app-text/iso-codes
+	systemd? ( sys-apps/systemd:= )
+	udev? ( virtual/libudev:= )
+	seccomp? ( sys-libs/libseccomp )
+
+	x11-libs/cairo:=
+	>=dev-libs/gobject-introspection-1.54:=
+"
+DEPEND="${COMMON_DEPEND}
+	media-libs/fontconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	seccomp? ( sys-apps/bubblewrap )
+	!<gnome-base/gnome-desktop-${PV}:3
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	gtk-doc? ( >=dev-util/gtk-doc-1.14 )
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	# Don't build manual test programs that will never get run
+	sed -i -e "/'test-.*'/d" libgnome-desktop/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dgnome_distributor=Gentoo
+		-Ddate_in_gnome_version=true
+		-Ddesktop_docs=true
+		$(meson_use debug debug_tools)
+		$(meson_feature udev)
+		$(meson_feature systemd)
+		$(meson_use gtk-doc gtk_doc)
+		-Dinstalled_tests=false
+		-Dbuild_gtk4=true
+		-Dlegacy_library=false
+	)
+	meson_src_configure
+}