games-engines/qtads: Add missing dev-qt/qtimageformats "5" slot dep

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/games-engines/qtads/qtads-3.3.0-r1.ebuild b/games-engines/qtads/qtads-3.3.0-r1.ebuild
new file mode 100644
index 000000000000..1df8c43516c6
--- /dev/null
+++ b/games-engines/qtads/qtads-3.3.0-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qmake-utils xdg
+
+DESCRIPTION="Multimedia interpreter for TADS text adventures"
+HOMEPAGE="https://realnc.github.io/qtads"
+SRC_URI="https://github.com/realnc/qtads/releases/download/v${PV}/${P}-source.tar.xz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+sound"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5[jpeg,png]
+	dev-qt/qtimageformats:5[mng]
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5[png]
+	sound? (
+		media-libs/libsdl2[sound]
+		media-libs/libsndfile
+		media-libs/libvorbis
+		media-sound/fluidsynth:0=
+		media-sound/mpg123
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	eqmake5 \
+		PREFIX="${EPREFIX}/usr" \
+		DOCDIR="${EPREFIX}/usr/share/${PF}" \
+		$(usev !sound CONFIG+=disable-audio) \
+		-after CONFIG-=silent
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+}