dev-util/radare2: Unbundle some libraries (bug #761247)

Libraries in question:
- dev-libs/libzip
- dev-libs/xxhash
- sys-apps/file (libmagic)
- sys-libs/zlib

Signed-off-by: mid-kid <esteve.varela@gmail.com>

 100.0% dev-util/radare2/

Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

2 files changed, 80 insertions, 0 deletions

diff --git a/dev-util/radare2/radare2-4.5.1-r1.ebuild b/dev-util/radare2/radare2-4.5.1-r1.ebuild
new file mode 100644
index 000000000000..2979f0f39ad6
--- /dev/null
+++ b/dev-util/radare2/radare2-4.5.1-r1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit bash-completion-r1 eutils toolchain-funcs
+
+DESCRIPTION="unix-like reverse engineering framework and commandline tools"
+HOMEPAGE="http://www.radare.org"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/radareorg/radare2"
+else
+	SRC_URI="https://github.com/radareorg/radare2/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="ssl libressl"
+
+RDEPEND="
+	dev-libs/libzip
+	dev-libs/xxhash
+	sys-apps/file
+	sys-libs/zlib
+	dev-libs/capstone:0=
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=("${FILESDIR}"/${PN}-4.5.1-docdir.patch)
+
+src_configure() {
+	# Ideally these should be set by ./configure
+	tc-export CC AR LD OBJCOPY RANLIB
+	export HOST_CC=${CC}
+
+	econf \
+		--without-libuv \
+		--with-syscapstone \
+		--with-sysmagic \
+		--with-sysxxhash \
+		--with-syszip \
+		$(use_with ssl openssl)
+}
+
+src_install() {
+	default
+
+	insinto /usr/share/zsh/site-functions
+	doins doc/zsh/_*
+
+	newbashcomp doc/bash_autocompletion.sh "${PN}"
+	bashcomp_alias "${PN}" rafind2 r2 rabin2 rasm2 radiff2
+
+	# a workaround for unstable $(INSTALL) call, bug #574866
+	local d
+	for d in doc/*; do
+		if [[ -d $d ]]; then
+			rm -rfv "$d" || die "failed to delete '$d'"
+		fi
+	done
+
+	# These are not really docs. radare assumes
+	# uncompressed files: bug #761250
+	docompress -x /usr/share/doc/${PF}/fortunes.{creepy,fun,nsfw,tips}
+}
diff --git a/dev-util/radare2/radare2-9999.ebuild b/dev-util/radare2/radare2-9999.ebuild
index 3c24d71a337c..e7065fb50acd 100644
--- a/dev-util/radare2/radare2-9999.ebuild
+++ b/dev-util/radare2/radare2-9999.ebuild
@@ -21,6 +21,10 @@ SLOT="0"
 IUSE="ssl libressl"
 
 RDEPEND="
+	dev-libs/libzip
+	dev-libs/xxhash
+	sys-apps/file
+	sys-libs/zlib
 	dev-libs/capstone:0=
 	ssl? (
 		!libressl? ( dev-libs/openssl:0= )
@@ -38,6 +42,9 @@ src_configure() {
 	econf \
 		--without-libuv \
 		--with-syscapstone \
+		--with-sysmagic \
+		--with-sysxxhash \
+		--with-syszip \
 		$(use_with ssl openssl)
 }