dev-python/pyjwt: Version bump to 1.5.2

Package-Manager: Portage-2.3.6, Repoman-2.3.2

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-python/pyjwt/pyjwt-1.5.2.ebuild b/dev-python/pyjwt/pyjwt-1.5.2.ebuild
new file mode 100644
index 000000000000..b10a65d7c1fb
--- /dev/null
+++ b/dev-python/pyjwt/pyjwt-1.5.2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_{4,5,6}} pypy )
+
+inherit distutils-r1 eutils
+
+MY_PN="PyJWT"
+
+DESCRIPTION="JSON Web Token implementation in Python"
+HOMEPAGE="https://github.com/progrium/pyjwt https://pypi.python.org/pypi/PyJWT/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="test"
+
+RDEPEND=""
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/pytest-runner[${PYTHON_USEDEP}]
+	test? (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-cov[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}"/${MY_PN}-${PV}
+
+python_prepare_all() {
+	find . -name '__pycache__' -prune -exec rm -rf {} \; || die "Cleaning __pycache__ failed"
+	find . -name '*.pyc' -exec rm -f {} \; || die "Cleaing *.pyc failed"
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	esetup.py test
+}
+
+pkg_postinst() {
+	elog "Available optional features:"
+	optfeature "cryptography" dev-python/cryptography
+	optfeature "flake8" dev-python/flake8
+
+	ewarn "flake8 feature requires 'flake8-import-order' and 'pep8-naming', which are not in portage yet"
+}