dev-libs/amdgpu-pro-opencl: bump to 20.40.1147286

Bug: https://bugs.gentoo.org/706406

Signed-off-by: Max Audron <audron@cocaine.farm>
Closes: https://github.com/gentoo/gentoo/pull/18131
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 100 insertions, 0 deletions

diff --git a/dev-libs/amdgpu-pro-opencl/Manifest b/dev-libs/amdgpu-pro-opencl/Manifest
index f7a861f101c2..d5cd4b3e792a 100644
--- a/dev-libs/amdgpu-pro-opencl/Manifest
+++ b/dev-libs/amdgpu-pro-opencl/Manifest
@@ -1,2 +1,3 @@
 DIST amdgpu-pro-18.20-684755-ubuntu-16.04.tar.xz 229474380 BLAKE2B f589aad71f093b74e37de40ac7c45ebbbeff93609b2fff1baaba711347a4641ef17acdcbe69d371372510a48bd48262cf6269c1f4d05e264023d52a425a423f2 SHA512 240e701acfde4ebe665cf69c8bd3710d036f450822aeb7ee2a21caab289af44167afda1d3b8d0dbe2c46c4e63d9b6fb5e96778311f342c26f334dc7beb4a2d5b
 DIST amdgpu-pro-19.30-838629-ubuntu-18.04.tar.xz 301833044 BLAKE2B ffdd49be431906c5ba20e9b285b44e368b40a70678177412d2329489c987567612f5262b64a9a1aef137cef603f77f768127d674c13488e13dddbc8732cf729c SHA512 7e8091dd37ae176d1ff131e5e2b13961f5a33fc7243052dce074dffb1468476f267d50a920182358188e44f4a93d0cbf39c5d430d56a9a2e09a67409e3478904
+DIST amdgpu-pro-20.40-1147286-ubuntu-20.04.tar.xz 333011308 BLAKE2B 82d0b728ee06bbc1a3dde579215a23397abb223caf7e2922b71dda9f31bebf13eaf5b1c5c7f25146dc2cfb31b57d16e848b0f902e599ed361e9285998cdb99fd SHA512 9b064a3b02d2a1ec18fdd6c098b70f4a8c6f93e4bfdc4e9a032ca387bdf7223278622c19d5bd55e493555c5f734168c3f2768cb743f9e00dcf5f96cbc399c7b3
diff --git a/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-20.40.1147286.ebuild b/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-20.40.1147286.ebuild
new file mode 100644
index 000000000000..4c69674212fb
--- /dev/null
+++ b/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-20.40.1147286.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MULTILIB_COMPAT=( abi_x86_{32,64} )
+
+inherit unpacker multilib-minimal
+
+SUPER_PN='amdgpu-pro'
+MY_PV=$(ver_rs 2 '-')
+
+DESCRIPTION="Proprietary OpenCL implementation for AMD GPUs"
+HOMEPAGE="https://www.amd.com/en/support/kb/release-notes/rn-amdgpu-unified-linux-20-40"
+SRC_URI="${SUPER_PN}-${MY_PV}-ubuntu-20.04.tar.xz"
+
+LICENSE="AMD-GPU-PRO-EULA"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RESTRICT="bindist mirror fetch strip"
+
+BDEPEND="dev-util/patchelf"
+COMMON=">=virtual/opencl-3"
+DEPEND="${COMMON}"
+RDEPEND="${COMMON}
+	!media-libs/mesa[opencl]" # Bug #686790
+
+QA_PREBUILT="/opt/amdgpu/lib*/*"
+
+S="${WORKDIR}/${SUPER_PN}-${MY_PV}-ubuntu-20.04"
+
+pkg_nofetch() {
+	local pkgver=$(ver_cut 1-2)
+	einfo "Please download Radeon Software for Linux version ${pkgver} for Ubuntu 20.04.1 from"
+	einfo "    ${HOMEPAGE}"
+	einfo "The archive should then be placed into your distfiles directory."
+}
+
+src_unpack() {
+	default
+
+	local ids_ver="1.0.0"
+	local patchlevel=$(ver_cut 3)
+	cd "${S}" || die
+	unpack_deb "${S}/libdrm-amdgpu-common_${ids_ver}-${patchlevel}_all.deb"
+	multilib_parallel_foreach_abi multilib_src_unpack
+}
+
+multilib_src_unpack() {
+	local libdrm_ver="2.4.100"
+	local patchlevel=$(ver_cut 3)
+	local deb_abi
+	[[ ${ABI} == x86 ]] && deb_abi=i386
+
+	mkdir -p "${BUILD_DIR}" || die
+	pushd "${BUILD_DIR}" >/dev/null || die
+	unpack_deb "${S}/opencl-orca-amdgpu-pro-icd_${MY_PV}_${deb_abi:-${ABI}}.deb"
+	unpack_deb "${S}/libdrm-amdgpu-amdgpu1_${libdrm_ver}-${patchlevel}_${deb_abi:-${ABI}}.deb"
+	popd >/dev/null || die
+}
+
+multilib_src_install() {
+	local dir_abi short_abi
+	[[ ${ABI} == x86 ]] && dir_abi=i386-linux-gnu && short_abi=32
+	[[ ${ABI} == amd64 ]] && dir_abi=x86_64-linux-gnu && short_abi=64
+
+	into "/opt/amdgpu"
+	patchelf --set-rpath '$ORIGIN' "opt/${SUPER_PN}/lib/${dir_abi}"/libamdocl-orca${short_abi}.so || die "Failed to fix library rpath"
+	dolib.so "opt/${SUPER_PN}/lib/${dir_abi}"/*
+	dolib.so "opt/amdgpu/lib/${dir_abi}"/*
+
+	insinto /etc/OpenCL/vendors
+	echo "/opt/amdgpu/$(get_libdir)/libamdocl-orca${short_abi}.so" \
+		> "${T}/${SUPER_PN}-${ABI}.icd" || die "Failed to generate ICD file for ABI ${ABI}"
+	doins "${T}/${SUPER_PN}-${ABI}.icd"
+}
+
+multilib_src_install_all() {
+	insinto "/opt/amdgpu"
+	doins -r opt/amdgpu/share
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		ewarn "Please note that using proprietary OpenCL libraries together with the"
+		ewarn "Open Source amdgpu stack is not officially supported by AMD. Do not ask them"
+		ewarn "for support in case of problems with this package."
+		ewarn ""
+		ewarn "Furthermore, if you have the whole AMDGPU-Pro stack installed this package"
+		ewarn "will almost certainly conflict with it. This might change once AMDGPU-Pro"
+		ewarn "has become officially supported by Gentoo."
+	fi
+
+	elog ""
+	elog "This package is now DEPRECATED on amd64 in favour of dev-libs/rocm-opencl-runtime."
+	elog "Moreover, it only provides legacy AMDGPU-Pro OpenCL libraries which are not compatible with Vega 10 and newer GPUs."
+	elog ""
+}