dev-lang/swi-prolog: bump development version

Package-Manager: Portage-3.0.4, Repoman-2.3.22
Signed-off-by: Keri Harris <keri@gentoo.org>

2 files changed, 105 insertions, 0 deletions

diff --git a/dev-lang/swi-prolog/Manifest b/dev-lang/swi-prolog/Manifest
index 61aa2c284851..01dfdd6dcf8a 100644
--- a/dev-lang/swi-prolog/Manifest
+++ b/dev-lang/swi-prolog/Manifest
@@ -3,3 +3,4 @@ DIST swipl-8.2.0.tar.gz 10955744 BLAKE2B 3f1a534a967c86054596fe8ec5fda41ae2ab09d
 DIST swipl-8.2.1.tar.gz 10969688 BLAKE2B 754678d9683999b681e62321423df01c4d28ac0aefb5b836134790112a76a2710cc3b433d381f4b11756727037cada026a2778445fe533f51a5543332ca86e82 SHA512 b49fa0832b4bad3b48256c97538172a06e7a4c50b55823dad345360f98055f0702e7a10fb2bfdb636e3fd99557bcb243cfccbaccb7546cb2afd13335f1c09db8
 DIST swipl-8.3.6.tar.gz 11016002 BLAKE2B 215fa94888ccd8cf7eba1aace28313d07cf09b07f02de5635944e1a622dd92379991af091e01a50161a05cc1dca6da2a35083a40e74888e001c9acda051b043e SHA512 9b5ba3d10d4a0d3699a20ca42bf6ce201a371eff3195d24c33db7a48cb0b5822d164f99acc05bf63b2f27f4924a048457b16819b105c38fe784bbb29a899a610
 DIST swipl-8.3.7.tar.gz 11014848 BLAKE2B 3ec8218edf387882b589f8420a86e327dddbc5b999fa2f4ad1a442c059998cebed01f4fbff6e26bfdcac9a0784477ea185b28740194cb614c48ae639c9acba8b SHA512 60ab400736e02f8833c95d5cd12528283866a8f717696707abe054348cffb462c2e78f2832bf5fc12cc4eec5400c35caaaf1552137860e6d07030a371034776d
+DIST swipl-8.3.8.tar.gz 11029755 BLAKE2B 7b97ed8b6cb391bf87eb6d7561b7f1f5d86dfe54b233dabd77c46b9c9f51148e9623e6d474be77ae1c004885895da9d2a9acf20dc4cd9697df500a2682294a8c SHA512 80b2e1a9e9d435b5ab061773a389b66eda2089dcc5ac617869532d5bd4fdd84e842c294e0e2d81f24330842ad58af1e66e54baa0cf91115db4808959331ca444
diff --git a/dev-lang/swi-prolog/swi-prolog-8.3.8.ebuild b/dev-lang/swi-prolog/swi-prolog-8.3.8.ebuild
new file mode 100644
index 000000000000..50482b3b3270
--- /dev/null
+++ b/dev-lang/swi-prolog/swi-prolog-8.3.8.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils eutils flag-o-matic multilib
+
+PATCHSET_VER="0"
+
+DESCRIPTION="versatile implementation of the Prolog programming language"
+HOMEPAGE="http://www.swi-prolog.org/"
+SRC_URI="http://www.swi-prolog.org/download/devel/src/swipl-${PV}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="archive berkdb debug doc +gmp java +libedit libressl minimal odbc pcre qt5 readline ssl test uuid X yaml"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-libs/ncurses:=
+	sys-libs/zlib
+	archive? ( app-arch/libarchive )
+	berkdb? ( >=sys-libs/db-4:= )
+	odbc? ( dev-db/unixODBC )
+	pcre? ( dev-libs/libpcre )
+	readline? ( sys-libs/readline:= )
+	libedit? ( dev-libs/libedit )
+	gmp? ( dev-libs/gmp:0 )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+	)
+	java? ( >=virtual/jdk-1.7:= )
+	uuid? ( dev-libs/ossp-uuid )
+	qt5? (
+		dev-qt/qtwidgets:5
+		dev-qt/qtgui:5
+	)
+	X? (
+		virtual/jpeg:0
+		x11-libs/libX11
+		x11-libs/libXft
+		x11-libs/libXinerama
+		x11-libs/libXpm
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM )
+	yaml? ( dev-libs/libyaml )"
+
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	java? ( test? ( =dev-java/junit-3.8* ) )"
+
+S="${WORKDIR}/swipl-${PV}"
+BUILD_DIR="${S}/build"
+CMAKE_USE_DIR="${S}"
+
+src_prepare() {
+	if [[ -d "${WORKDIR}"/${PV} ]] ; then
+		eapply "${WORKDIR}"/${PV}
+	fi
+	eapply_user
+
+	sed -i -e "s|\(SWIPL_INSTALL_PREFIX\)   lib/.*)|\1   $(get_libdir)/swipl)|" CMakeLists.txt || die
+	sed -i -e "s|\(SWIPL_INSTALL_CMAKE_CONFIG_DIR\) lib/|\1   $(get_libdir)/|" CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+	use debug && append-flags -DO_DEBUG
+
+	mycmakeargs=(
+		-DSWIPL_INSTALL_PREFIX=$(get_libdir)/swipl
+		-DUSE_GMP=$(usex gmp)
+		-DINSTALL_DOCUMENTATION=$(use doc && usex archive)
+		-DSWIPL_PACKAGES_BASIC=$(usex !minimal)
+		-DSWIPL_PACKAGES_ARCHIVE=$(usex archive)
+		-DSWIPL_PACKAGES_ODBC=$(usex odbc)
+		-DSWIPL_PACKAGES_BDB=$(usex berkdb)
+		-DSWIPL_PACKAGES_PCRE=$(usex pcre)
+		-DSWIPL_PACKAGES_YAML=$(usex yaml)
+		-DSWIPL_PACKAGES_SSL=$(usex ssl)
+		-DSWIPL_PACKAGES_JAVA=$(usex java)
+		-DSWIPL_PACKAGES_QT=$(usex qt5)
+		-DSWIPL_PACKAGES_X=$(usex X)
+		-DSWIPL_PACKAGES_TERM=$(if use libedit || use readline; then echo yes; else echo no; fi)
+		)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	XDG_CONFIG_DIRS="${HOME}" \
+	XDG_DATA_DIRS="${HOME}" \
+		cmake-utils_src_compile
+}
+
+src_test() {
+	USE_PUBLIC_NETWORK_TESTS=false \
+	USE_ODBC_TESTS=false \
+		cmake-utils_src_test -V
+}