dev-lang/swi-prolog: bump development version

Signed-off-by: Keri Harris <keri@gentoo.org>

2 files changed, 105 insertions, 0 deletions

diff --git a/dev-lang/swi-prolog/Manifest b/dev-lang/swi-prolog/Manifest
index 5c8492e04cbd..22db0a0dfd6b 100644
--- a/dev-lang/swi-prolog/Manifest
+++ b/dev-lang/swi-prolog/Manifest
@@ -5,3 +5,4 @@ DIST swipl-8.2.3.tar.gz 10999577 BLAKE2B 57cfa9f6fb97f0136a35da1850c7ae8da123d1c
 DIST swipl-8.3.18.tar.gz 11121028 BLAKE2B 9b5bca6cb2f11918e51f687d3f330f021cc207c029e58dff7e5cbb03c47a908878c56dded8b9a4df2a67e86c2dd28400462a8484802eb18cb0eb2454a96e59a0 SHA512 6a7845c807b7ef41b501bd53d7e11208cac95bb57ac2096c8e00dd2740987faa61bf7b5201b3abf879770bc7a0935ed377458bf84de0298696741c812c009a65
 DIST swipl-8.3.19.tar.gz 11135612 BLAKE2B 89e7b4dbfca9b52217ee55439bb6892344d322b4d99719755fb34f9503448c4d3b018d73a95094c31f51cb514ee09121822b579d6c94969ebad6553548136bbd SHA512 1b2acc0006f2d29113ffa51595b53883e7c903419c47ea137954922241f03ce5d6c28e07e4e4d89da228db531af9e42678cd36fcd854495b8d091e809c8e249b
 DIST swipl-8.3.20.tar.gz 11136550 BLAKE2B 83dd6ea056fd579816b88ca1faa3f857cb880d39d0cebc186aab0a0bf7cfdde19348874d4a7efb5e27995adfffb3ee075c42aa7fde1088ee17a5a05c137667ed SHA512 7f64ba639db0e1d75bd459e61ec14c30498035bbb59995f888702174fac159ebc96c47f22be2c3e466f5ba5547b39aaf83d296da2b2419ed89ff9195f355f3a4
+DIST swipl-8.3.21.tar.gz 11143843 BLAKE2B 4e4a009e40609d17f33bd783c477295e20805d471ffdb8f6451b52a7c51a749c123e79d0e5087a473fe20c5a673648208540e7039403c35c7ffb044851f72f04 SHA512 fe8596a4d0ecc5d2d48e7532619bdf09364d1b52beffc4ea73cdd79d29dde9d68ddc1a66a4f2f579d7eee1a3e215e13e918ca59b26788957e5e2dd5af2905139
diff --git a/dev-lang/swi-prolog/swi-prolog-8.3.21.ebuild b/dev-lang/swi-prolog/swi-prolog-8.3.21.ebuild
new file mode 100644
index 000000000000..c9064992abbc
--- /dev/null
+++ b/dev-lang/swi-prolog/swi-prolog-8.3.21.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils eutils flag-o-matic multilib
+
+PATCHSET_VER="0"
+
+DESCRIPTION="versatile implementation of the Prolog programming language"
+HOMEPAGE="http://www.swi-prolog.org/"
+SRC_URI="http://www.swi-prolog.org/download/devel/src/swipl-${PV}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="archive berkdb debug doc +gmp java +libedit libressl minimal odbc pcre qt5 readline ssl test uuid X yaml"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-libs/ncurses:=
+	sys-libs/zlib
+	archive? ( app-arch/libarchive )
+	berkdb? ( >=sys-libs/db-4:= )
+	odbc? ( dev-db/unixODBC )
+	pcre? ( dev-libs/libpcre )
+	readline? ( sys-libs/readline:= )
+	libedit? ( dev-libs/libedit )
+	gmp? ( dev-libs/gmp:0 )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+	)
+	java? ( >=virtual/jdk-1.7:= )
+	uuid? ( dev-libs/ossp-uuid )
+	qt5? (
+		dev-qt/qtwidgets:5
+		dev-qt/qtgui:5
+	)
+	X? (
+		virtual/jpeg:0
+		x11-libs/libX11
+		x11-libs/libXft
+		x11-libs/libXinerama
+		x11-libs/libXpm
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM )
+	yaml? ( dev-libs/libyaml )"
+
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	java? ( test? ( =dev-java/junit-3.8* ) )"
+
+S="${WORKDIR}/swipl-${PV}"
+BUILD_DIR="${S}/build"
+CMAKE_USE_DIR="${S}"
+
+src_prepare() {
+	if [[ -d "${WORKDIR}"/${PV} ]] ; then
+		eapply "${WORKDIR}"/${PV}
+	fi
+	eapply_user
+
+	sed -i -e "s|\(SWIPL_INSTALL_PREFIX\)   lib/.*)|\1   $(get_libdir)/swipl)|" CMakeLists.txt || die
+	sed -i -e "s|\(SWIPL_INSTALL_CMAKE_CONFIG_DIR\) lib/|\1   $(get_libdir)/|" CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+	use debug && append-flags -DO_DEBUG
+
+	mycmakeargs=(
+		-DSWIPL_INSTALL_PREFIX=$(get_libdir)/swipl
+		-DUSE_GMP=$(usex gmp)
+		-DINSTALL_DOCUMENTATION=$(use doc && usex archive)
+		-DSWIPL_PACKAGES_BASIC=$(usex !minimal)
+		-DSWIPL_PACKAGES_ARCHIVE=$(usex archive)
+		-DSWIPL_PACKAGES_ODBC=$(usex odbc)
+		-DSWIPL_PACKAGES_BDB=$(usex berkdb)
+		-DSWIPL_PACKAGES_PCRE=$(usex pcre)
+		-DSWIPL_PACKAGES_YAML=$(usex yaml)
+		-DSWIPL_PACKAGES_SSL=$(usex ssl)
+		-DSWIPL_PACKAGES_JAVA=$(usex java)
+		-DSWIPL_PACKAGES_QT=$(usex qt5)
+		-DSWIPL_PACKAGES_X=$(usex X)
+		-DSWIPL_PACKAGES_TERM=$(if use libedit || use readline; then echo yes; else echo no; fi)
+		)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	XDG_CONFIG_DIRS="${HOME}" \
+	XDG_DATA_DIRS="${HOME}" \
+		cmake-utils_src_compile
+}
+
+src_test() {
+	USE_PUBLIC_NETWORK_TESTS=false \
+	USE_ODBC_TESTS=false \
+		cmake-utils_src_test -V
+}