dev-lang/mozart: version bump

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Keri Harris <keri@gentoo.org>

2 files changed, 101 insertions, 0 deletions

diff --git a/dev-lang/mozart/Manifest b/dev-lang/mozart/Manifest
index fd420dc7f17a..f18a5f097ff4 100644
--- a/dev-lang/mozart/Manifest
+++ b/dev-lang/mozart/Manifest
@@ -2,3 +2,5 @@ DIST mozart-1.4.0-gentoo-patchset-5.tar.gz 24700 BLAKE2B c3b14bd7d8a762b84a098a9
 DIST mozart-1.4.0-gentoo-patchset-6.tar.gz 25878 BLAKE2B 831fa3accc587c769ab40ae4289e45ca28171af572095b7c3b93b69e82ff4bcaeb425d68c7a76aa9b2724b610ba21020647b6d1e3aa525ce58edbc9446d88791 SHA512 5a292bcc81c8062ebd5a948b224e8131302fc61b60303b8e3257ed20e751d0a874303611aeba6d1aacddbf92ec611428e49c2c17bc1dff5e182d0198afe655bf
 DIST mozart-1.4.0.20080704-doc.tar.gz 4085020 BLAKE2B 33eaf57c91dd62d9aa79651095aa5d095086d76dfa16bd5f520962229338c00556fcf3ac01eca1769c687f990110e95fa887d56391346af780d55166708338a1 SHA512 25f8f4b603ae7f4ef054a79a2baa4e10074f8a95f762b75fd88480526fb073b5b4874c269d116a960017a9e7ef989dd9f41853b0ff76e08b2cad2de2090c2eb4
 DIST mozart-1.4.0.20080704-src.tar.gz 11848201 BLAKE2B 0ceeb7dbd3f6858d1a4fee76f2a99eeb3127a07fd31b6760748ac8b8b638c36caaa873154be6481c3dc4b5196ef04cb0c10be421bd87dc3bc4e6b29357622d8d SHA512 f1114662c8c603cc2ac530d4ea1d22a0581f6e1b4d5cb57ccf899b8051ea48dbcf2fa2b62173359a754367a5456a7cb121a208d6a246248207599b0470525229
+DIST mozart-2.0.1-gentoo-patchset-0.tar.gz 10888 BLAKE2B 2b41560021bec70bb60cfb4439b5db13a6e7ac7d7b1b7e1be6fd584f5e7de566db40f67fccec66f53a39150b1985a4e41a45cbd41aa8b77ff740fd60ce708f05 SHA512 082187494ef4c7a5655bde22d9b6df9c37fada5512cae2f15440dd298229e48777d1de4a2461f127279fa8f36da9900c78c6927fbde03bfa4d2006200923e33e
+DIST mozart-2.0.1.tar.gz 2281261 BLAKE2B 7f071e9ec130a0b482b299f4dac15d64f632702d6ecf55b7af0993087064e533b4de80f77520a725f69f68648a9ce763c8c8826bb24e52af49eda8c3ccfba0b5 SHA512 a72a6fa68296d06af72327fd11310b3be152e5ad9a56f1fc4200ac7b89cd177e9a23a38c6721e1885d4f2ed0870065e919fb9fe3c9a2833fcd8e4ac0fd43aeb4
diff --git a/dev-lang/mozart/mozart-2.0.1.ebuild b/dev-lang/mozart/mozart-2.0.1.ebuild
new file mode 100644
index 000000000000..f5be42ff3911
--- /dev/null
+++ b/dev-lang/mozart/mozart-2.0.1.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils java-pkg-2 java-ant-2
+
+PATCHSET_VER="0"
+
+DESCRIPTION="Advanced development platform for intelligent, distributed applications"
+HOMEPAGE="http://mozart2.org/"
+SRC_URI="https://github.com/mozart/mozart2/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	https://dev.gentoo.org/~keri/distfiles/mozart/${P}-gentoo-patchset-${PATCHSET_VER}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="emacs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-libs/boost:=
+	dev-libs/gmp:0
+	dev-lang/tcl:0
+	dev-lang/tk:0
+	emacs? ( >=app-editors/emacs-23.1:* )"
+
+DEPEND="${RDEPEND}
+	dev-java/ant-core
+	>=virtual/jdk-1.8:=
+	|| (
+		dev-lang/scala:=
+		dev-lang/scala-bin:=
+	)
+	test? ( dev-cpp/gtest:= )"
+
+S="${WORKDIR}/${PN}2-${PV}"
+BUILD_DIR="${S}/build"
+CMAKE_USE_DIR="${S}"
+
+src_prepare() {
+	if [[ -d "${WORKDIR}"/${PV} ]] ; then
+		eapply "${WORKDIR}"/${PV}
+	fi
+	eapply_user
+
+	touch "${S}"/stdlib/CMakeLists.txt
+	touch "${S}"/vm/vm/test/gtest/CMakeLists.txt
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DMOZART_BOOST_USE_STATIC_LIBS=OFF
+		-DEMACS=$(if use emacs; then echo /usr/bin/emacs; fi)
+		)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	if has_version "dev-lang/scala"; then
+		EANT_GENTOO_CLASSPATH="scala"
+	else
+		EANT_GENTOO_CLASSPATH="scala-bin"
+	fi
+	cd "${S}"/bootcompiler
+	ANT_OPTS="-Xss2M" eant jar
+
+	cd "${S}"
+	cmake-utils_src_compile
+}
+
+src_test() {
+	cmake-utils_src_compile vmtest platform-test
+	cmake-utils_src_test -V
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	cd "${BUILD_DIR}"
+	dolib.so vm/vm/main/libmozartvm.so
+	dolib.so vm/boostenv/main/libmozartvmboost.so
+}
+
+pkg_postinst() {
+	if use emacs; then
+		xdg_icon_cache_update
+		xdg_desktop_database_update
+	fi
+}
+
+pkg_postrm() {
+	if use emacs; then
+		xdg_icon_cache_update
+		xdg_desktop_database_update
+	fi
+}