dev-games/ode: port to EAPI 7

Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 93 insertions, 49 deletions

diff --git a/dev-games/ode/ode-0.11.1.ebuild b/dev-games/ode/ode-0.11.1.ebuild
index b06d5c927c9e..03338b82af9b 100644
--- a/dev-games/ode/ode-0.11.1.ebuild
+++ b/dev-games/ode/ode-0.11.1.ebuild
@@ -1,8 +1,7 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
-inherit ltprune
+EAPI=7
 
 DESCRIPTION="Open Dynamics Engine SDK"
 HOMEPAGE="http://ode.org/"
@@ -13,13 +12,19 @@ SLOT="0"
 KEYWORDS="amd64 x86"
 IUSE="debug doc double-precision examples gyroscopic static-libs"
 
-RDEPEND="examples? (
+RDEPEND="
+	examples? (
 		virtual/opengl
-	)"
-DEPEND="${RDEPEND}
-	doc? ( app-doc/doxygen )"
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="doc? ( app-doc/doxygen )"
+
+DOCS=( CHANGELOG.txt README.txt )
 
 src_prepare() {
+	default
+
 	sed -i \
 		-e "s:\$.*/drawstuff/textures:/usr/share/doc/${PF}/examples:" \
 		drawstuff/src/Makefile.in \
@@ -41,6 +46,7 @@ src_configure() {
 
 src_compile() {
 	emake
+
 	if use doc ; then
 		cd ode/doc
 		doxygen Doxyfile || die
@@ -48,23 +54,31 @@ src_compile() {
 }
 
 src_install() {
-	DOCS="CHANGELOG.txt README.txt" \
-		default
-	prune_libtool_files
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+
 	if use doc ; then
-		dohtml docs/*
+		docinto html
+		dodoc docs/*
 	fi
-	if use examples; then
-		cd ode/demo
+
+	if use examples ; then
+		cd ode/demo || die
+
 		exeinto /usr/share/doc/${PF}/examples
+
 		local f
 		for f in *.c* ; do
 			doexe .libs/${f%.*}
 		done
-		cd ../..
+
+		cd ../.. || die
+
 		doexe drawstuff/dstest/dstest
-		insinto /usr/share/doc/${PF}/examples
-		doins ode/demo/*.{c,cpp,h} \
+
+		docinto examples
+		dodoc ode/demo/*.{c,cpp,h} \
 			drawstuff/textures/*.ppm \
 			drawstuff/dstest/dstest.cpp \
 			drawstuff/src/{drawstuff.cpp,internal.h,x11.cpp}
diff --git a/dev-games/ode/ode-0.12.ebuild b/dev-games/ode/ode-0.12.ebuild
index a1b352d94fa3..c5e93ccbf22c 100644
--- a/dev-games/ode/ode-0.12.ebuild
+++ b/dev-games/ode/ode-0.12.ebuild
@@ -1,8 +1,7 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
-inherit ltprune
+EAPI=7
 
 DESCRIPTION="Open Dynamics Engine SDK"
 HOMEPAGE="http://ode.org/"
@@ -13,13 +12,19 @@ SLOT="0"
 KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
 IUSE="debug doc double-precision examples gyroscopic static-libs"
 
-RDEPEND="examples? (
+RDEPEND="
+	examples? (
 		virtual/opengl
-	)"
-DEPEND="${RDEPEND}
-	doc? ( app-doc/doxygen )"
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="doc? ( app-doc/doxygen )"
+
+DOCS=( CHANGELOG.txt README.txt )
 
 src_prepare() {
+	default
+
 	sed -i \
 		-e "s:\$.*/drawstuff/textures:/usr/share/doc/${PF}/examples:" \
 		drawstuff/src/Makefile.in \
@@ -41,30 +46,38 @@ src_configure() {
 
 src_compile() {
 	emake
+
 	if use doc ; then
-		cd ode/doc
+		cd ode/doc || die
 		doxygen Doxyfile || die
 	fi
 }
 
 src_install() {
-	DOCS="CHANGELOG.txt README.txt" \
-		default
-	prune_libtool_files
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+
 	if use doc ; then
-		dohtml docs/*
+		docinto html
+		dodoc docs/*
 	fi
-	if use examples; then
-		cd ode/demo
+
+	if use examples ; then
+		cd ode/demo || die
+
 		exeinto /usr/share/doc/${PF}/examples
+
 		local f
 		for f in *.c* ; do
 			doexe .libs/${f%.*}
 		done
-		cd ../..
+
+		cd ../.. || die
+
 		doexe drawstuff/dstest/dstest
-		insinto /usr/share/doc/${PF}/examples
-		doins ode/demo/*.{c,cpp,h} \
+		docinto examples
+		dodoc ode/demo/*.{c,cpp,h} \
 			drawstuff/textures/*.ppm \
 			drawstuff/dstest/dstest.cpp \
 			drawstuff/src/{drawstuff.cpp,internal.h,x11.cpp}
diff --git a/dev-games/ode/ode-0.14-r1.ebuild b/dev-games/ode/ode-0.14-r1.ebuild
index d50555084059..98865c663c91 100644
--- a/dev-games/ode/ode-0.14-r1.ebuild
+++ b/dev-games/ode/ode-0.14-r1.ebuild
@@ -1,8 +1,9 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
-inherit autotools epatch ltprune
+EAPI=7
+
+inherit autotools
 
 DESCRIPTION="Open Dynamics Engine SDK"
 HOMEPAGE="http://ode.org/"
@@ -13,16 +14,25 @@ SLOT="0/6"
 KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
 IUSE="debug doc double-precision examples gyroscopic static-libs"
 
-RDEPEND="examples? (
-	virtual/glu
-	virtual/opengl )"
-DEPEND="${RDEPEND}
-	doc? ( app-doc/doxygen )"
+RDEPEND="
+	examples? (
+		virtual/glu
+		virtual/opengl
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="doc? ( app-doc/doxygen )"
 
 MY_EXAMPLES_DIR=/usr/share/doc/${PF}/examples
 
+DOCS=( CHANGELOG.txt README.md )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.14-gcc7.patch
+)
+
 src_prepare() {
-	epatch "${FILESDIR}"/${PN}-0.14-gcc7.patch
+	default
 
 	sed -i \
 		-e "s:\$.*/drawstuff/textures:${MY_EXAMPLES_DIR}:" \
@@ -47,28 +57,35 @@ src_configure() {
 src_compile() {
 	emake
 	if use doc ; then
-		cd ode/doc
+		cd ode/doc || die
 		doxygen Doxyfile || die
 	fi
 }
 
 src_install() {
-	DOCS="CHANGELOG.txt README.md" \
-		default
-	prune_libtool_files
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+
 	if use doc ; then
-		dohtml docs/*
+		docinto html
+		dodoc docs/*
 	fi
-	if use examples; then
-		docompress -x "${MY_EXAMPLES_DIR}"
-		insinto "${MY_EXAMPLES_DIR}"
-		exeinto "${MY_EXAMPLES_DIR}"
+
+	if use examples ; then
+		docompress -x ${MY_EXAMPLES_DIR}
+
+		insinto ${MY_EXAMPLES_DIR}
+		exeinto ${MY_EXAMPLES_DIR}
+
 		doexe drawstuff/dstest/dstest
 		doins ode/demo/*.{c,cpp,h} \
 			drawstuff/textures/*.ppm \
 			drawstuff/dstest/dstest.cpp \
 			drawstuff/src/{drawstuff.cpp,internal.h,x11.cpp}
-		cd ode/demo
+
+		cd ode/demo || die
+
 		local f
 		for f in *.c* ; do
 			doexe .libs/${f%.*}