app-shells/dash: add 9999

dash releases are infrequent. Further, there's various POSIX.1-2024 changes
in git which may be useful to test.

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 78 insertions, 3 deletions

diff --git a/app-shells/dash/dash-0.5.12.ebuild b/app-shells/dash/dash-0.5.12.ebuild
index 7659ef8d0f3b..951b11271623 100644
--- a/app-shells/dash/dash-0.5.12.ebuild
+++ b/app-shells/dash/dash-0.5.12.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -7,11 +7,16 @@ inherit flag-o-matic toolchain-funcs
 
 DESCRIPTION="Debian Almquist Shell"
 HOMEPAGE="http://gondor.apana.org.au/~herbert/dash/"
-SRC_URI="http://gondor.apana.org.au/~herbert/dash/files/${P}.tar.gz"
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://git.kernel.org/pub/scm/utils/dash/dash.git"
+	inherit autotools git-r3
+else
+	SRC_URI="http://gondor.apana.org.au/~herbert/dash/files/${P}.tar.gz"
+	KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+fi
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
 IUSE="libedit static"
 
 BDEPEND="virtual/pkgconfig"
@@ -27,6 +32,8 @@ src_prepare() {
 	# Fix the invalid sort
 	sed -i -e 's/LC_COLLATE=C/LC_ALL=C/g' src/mkbuiltins || die
 
+	[[ ${PV} == 9999 ]] && eautoreconf
+
 	# Use pkg-config for libedit linkage
 	sed -i \
 		-e "/LIBS/s:-ledit:\`$(tc-getPKG_CONFIG) --libs libedit $(usex static --static '')\`:" \
diff --git a/app-shells/dash/dash-9999.ebuild b/app-shells/dash/dash-9999.ebuild
new file mode 100644
index 000000000000..0c10e51d5343
--- /dev/null
+++ b/app-shells/dash/dash-9999.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="Debian Almquist Shell"
+HOMEPAGE="http://gondor.apana.org.au/~herbert/dash/"
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://git.kernel.org/pub/scm/utils/dash/dash.git"
+	inherit autotools git-r3
+else
+	SRC_URI="http://gondor.apana.org.au/~herbert/dash/files/${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="libedit static"
+
+BDEPEND="virtual/pkgconfig"
+RDEPEND="!static? ( libedit? ( dev-libs/libedit ) )"
+DEPEND="
+	${RDEPEND}
+	libedit? ( static? ( dev-libs/libedit[static-libs] ) )
+"
+
+src_prepare() {
+	default
+
+	# Fix the invalid sort
+	sed -i -e 's/LC_COLLATE=C/LC_ALL=C/g' src/mkbuiltins || die
+
+	[[ ${PV} == 9999 ]] && eautoreconf
+
+	# Use pkg-config for libedit linkage
+	sed -i \
+		-e "/LIBS/s:-ledit:\`$(tc-getPKG_CONFIG) --libs libedit $(usex static --static '')\`:" \
+		configure || die
+}
+
+src_configure() {
+	if [[ ${CHOST} == *-solaris* ]] ; then
+		# don't redefine stat, open, dirent, etc. on Solaris
+		export ac_cv_func_stat64=yes
+		export ac_cv_func_open64=yes
+	fi
+
+	if [[ ${CHOST} == powerpc-*-darwin* ]] ; then
+		sed -i -e 's/= stpncpy(s, \([^,]\+\), \([0-9]\+\))/+= snprintf(s, \2, "%s", \1)/' \
+			src/jobs.c || die
+	fi
+
+	use static && append-ldflags -static
+
+	append-cppflags -DJOBS=$(usex libedit 1 0)
+
+	# Do not pass --enable-glob due to #443552.
+	local myeconfargs=(
+		CC_FOR_BUILD="$(tc-getBUILD_CC)"
+		--bindir="${EPREFIX}"/bin
+		--enable-fnmatch
+		$(use_with libedit)
+	)
+
+	econf "${myeconfargs[@]}"
+}