app-misc/hivex: bump, cleanup, seems okay

Package-Manager: Portage-2.3.5, Repoman-2.3.2

3 files changed, 104 insertions, 1 deletions

diff --git a/app-misc/hivex/Manifest b/app-misc/hivex/Manifest
index f027ce845d27..24881d0728ea 100644
--- a/app-misc/hivex/Manifest
+++ b/app-misc/hivex/Manifest
@@ -1 +1,2 @@
 DIST hivex-1.3.11.tar.gz 1264487 SHA256 c63adf6c7ef9140acf20775d35bef35ab563c0d2f59d3dfb8e0d15cfa7c77678 SHA512 1ff9fbcfb976fea5bba41c5ff06e4dc68af0e507accc236ca0406644ee2c865619b3b3bf9550124778fcd782ddc257f1d89861b45f48c0c3ceed18dfa1e02ced WHIRLPOOL 6d741ad14660390b2c171bff400645cbcd20a991a55b7fb4e349c864e2dd4e606f57f344d8b851acf87d12bf8a3b608a77c073c565d9aa55cd23094d7e09e8cd
+DIST hivex-1.3.14.tar.gz 1332257 SHA256 eb5cb29f5eb41185688cc1be454895b53c1965578f036ebf31ac32992f121b2b SHA512 dd7dd52dceda580179a815fc48a2a2c7e8f7234614beceb937fba7e317df17984e65453338160c4c467b70d7d4f9bd61b48aad3ca51e19bd5e4cfbca8ee3adb6 WHIRLPOOL 51395c0915d88e167e9909a856c975865751de9c37aeee5fde7c64875569b08ad70c9987b35d949dee9fc01b616827abeb276f2464982521a31199c478932366
diff --git a/app-misc/hivex/hivex-1.3.11-r1.ebuild b/app-misc/hivex/hivex-1.3.11-r1.ebuild
index 08501b96c9df..d06946aa4b41 100644
--- a/app-misc/hivex/hivex-1.3.11-r1.ebuild
+++ b/app-misc/hivex/hivex-1.3.11-r1.ebuild
@@ -5,7 +5,7 @@ EAPI=5
 
 AUTOTOOLS_IN_SOURCE_BUILD=1
 
-USE_RUBY="ruby20 ruby21"
+USE_RUBY="ruby21"
 RUBY_OPTIONAL=yes
 
 PYTHON_COMPAT=(python2_7 python3_{4,5,6})
diff --git a/app-misc/hivex/hivex-1.3.14.ebuild b/app-misc/hivex/hivex-1.3.14.ebuild
new file mode 100644
index 000000000000..dd48bcb9adfa
--- /dev/null
+++ b/app-misc/hivex/hivex-1.3.14.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+USE_RUBY="ruby21 ruby22 ruby23"
+RUBY_OPTIONAL=yes
+
+PYTHON_COMPAT=(python2_7 python3_{4,5,6})
+
+inherit eutils perl-module ruby-ng python-single-r1
+
+DESCRIPTION="Library for reading and writing Windows Registry 'hive' binary files"
+HOMEPAGE="http://libguestfs.org"
+SRC_URI="http://libguestfs.org/download/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ocaml readline +perl python test static-libs ruby"
+
+RDEPEND="
+	virtual/libiconv
+	virtual/libintl
+	dev-libs/libxml2:2
+	ocaml? ( dev-lang/ocaml[ocamlopt]
+			 dev-ml/findlib[ocamlopt]
+			 )
+	readline? ( sys-libs/readline:0 )
+	perl? ( dev-perl/IO-stringy )
+	ruby? ( $(ruby_implementations_depend) )
+	python? ( ${PYTHON_DEPS} )
+	"
+
+DEPEND="${RDEPEND}
+	perl? (
+		test? ( dev-perl/Pod-Coverage
+			dev-perl/Test-Pod-Coverage )
+		  )
+	"
+
+ruby_add_bdepend "ruby? ( dev-ruby/rake
+			virtual/rubygems
+			dev-ruby/rdoc )"
+ruby_add_rdepend "ruby? ( virtual/rubygems )"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
+			ruby? ( || ( $(ruby_get_use_targets) ) )"
+
+DOCS=( README )
+
+S="${WORKDIR}/${P}"
+
+pkg_setup() {
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_unpack() {
+	default
+	cp -prlP "${WORKDIR}/${P}" "${WORKDIR}"/all
+}
+
+src_configure() {
+	ruby-ng_src_configure
+
+	if use perl; then
+		pushd perl
+		perl-module_src_configure
+		popd
+	fi
+
+	local myeconfargs=(
+		$(use_with readline)
+		$(use_enable ocaml)
+		$(use_enable perl)
+		--enable-nls
+		--disable-ruby
+		$(use_enable python)
+		--disable-rpath
+		)
+
+	econf ${myeconfargs[@]}
+}
+
+src_compile() {
+	default
+	ruby-ng_src_compile
+}
+
+src_install() {
+	strip-linguas -i po
+
+	emake install DESTDIR="${ED}" "LINGUAS=""${LINGUAS}"""
+
+	ruby-ng_src_install
+
+	if use perl; then
+		perl_delete_localpod
+	fi
+}