app-laptop/mbpfan: drop 2.3.0

Signed-off-by: Göktürk Yüksek <gokturk@gentoo.org>

1 files changed, 0 insertions, 47 deletions

diff --git a/app-laptop/mbpfan/mbpfan-2.3.0.ebuild b/app-laptop/mbpfan/mbpfan-2.3.0.ebuild
deleted file mode 100644
index bd8776fe6b10..000000000000
--- a/app-laptop/mbpfan/mbpfan-2.3.0.ebuild
+++ /dev/null
@@ -1,47 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit linux-info systemd toolchain-funcs
-
-DESCRIPTION="A simple daemon to control fan speed on all Macbook/Macbook Pros"
-HOMEPAGE="https://github.com/dgraziotin/mbpfan"
-
-if [[ ${PV} == *9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/dgraziotin/${PN}.git"
-else
-	SRC_URI="https://github.com/dgraziotin/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64"
-fi
-
-LICENSE="GPL-3+"
-SLOT="0"
-RESTRICT="test" # will fail if the hardware is unavailable, not useful
-
-CONFIG_CHECK="~SENSORS_APPLESMC ~SENSORS_CORETEMP"
-
-src_compile() {
-	emake CC="$(tc-getCC)"
-}
-
-src_install() {
-	emake DESTDIR="${ED}" install
-
-	# Decompress the man page to enable PM auto compression
-	gzip -d "${ED}"/usr/share/man/man8/mbpfan.8.gz || die
-
-	# Remove the empty systemd unit directory
-	# It doesn't actually install the unit file
-	rmdir --ignore-fail-on-non-empty -p "${ED}"/lib/systemd/system || die
-	# Actually install the sytstemd unit file
-	systemd_dounit ${PN}.service
-	# Install openrc init file
-	newinitd ${PN}.init.gentoo ${PN}
-
-	# make install doesn't install the docs in the right place
-	rm -r "${ED}"/usr/share/doc/${PN} || die
-
-	einstalldocs
-}