dev-lang/python-exec: import vanilla

7 files changed, 417 insertions, 0 deletions

diff --git a/dev-lang/python-exec/Manifest b/dev-lang/python-exec/Manifest
new file mode 100644
index 0000000000..2f04c2e604
--- /dev/null
+++ b/dev-lang/python-exec/Manifest
@@ -0,0 +1,4 @@
+DIST python-exec-2.0.1.tar.bz2 80965 SHA256 3eddcb0d6c682a5c182c62578bb8d6ce1140a009873747e9ba1bf9de72ed7efd SHA512 0396e2617c759a66b16e57b0ca60b57e03f3c8096ae4a7f2e402eafcbee4ffd839bf0c6e4d259c6ba90940f9ba7e3f191125e395080cce3ef82e5f52053d0462 WHIRLPOOL 50c0cac1c7e2b5d2a21125647874c83caeabee293b87ef01926474d492b79b7837754c2d26173282977e9d00024559bb070f8d76bb5227df1776e937cd280c32
+DIST python-exec-2.0.2.tar.bz2 82217 SHA256 c411638fe94953c1e8ff57e7b66f601a817633fbc9cb7d410982778042051bb0 SHA512 96198dda88a73b902d617a32f10ddf2ac981b1871fb5eaf5003d77453df8a0aacf299c39c6e49ebaa620994a30e57ee7a1128fb4ba41aa4f503031fa2addef7f WHIRLPOOL 603b494c7b87f0f3f0cfba35378e1a2e231879a01b730657e09ecf798957fa4dfd54a6d852074c2aa9ae3c15e5d1d3203584b8a120e5dd0dee2117319706a5ce
+DIST python-exec-2.1.tar.bz2 82167 SHA256 adac4e9ae677ca0fbb9efc55573ecbb0e8361ed7a60a5241e7abc1056fba06ad SHA512 cadfb7723aa412caec4a449909769b14a800c19650c64768b0ffb30b2c0645e70c9a039f960f3263c6c18490bb73c0129b83a72c7407f558bcaf3652cc4c8bcf WHIRLPOOL 72b73b216faf7caa8afbc3ce316771bd832e468cf84835267dc3833d5c52fce24578e09f2d3aa8a322f324426eda5e53bd9611711ea976679574b2be764c2525
+DIST python-exec-2.4.3.tar.bz2 86815 SHA256 581aa0c033632269d553754440d4017c21afc1c1500fd8951de093bc715c63fb SHA512 37fb7f915a2848699e9fca4e09d167b6d6aa192e3c374d7f01aec09529b5f1346ce2c45139f4e8f68b53e3f197b4d77b7f58519b012c117dd5ec8535a43fbe34 WHIRLPOOL 117564deb6f35387757ebbbff96d0325d5979d2933bbfca184cde0170cdd923bf9fa71ba76f234b098df12f006b6f8b5ba388416692ceff56ec7c16173777ab6
diff --git a/dev-lang/python-exec/metadata.xml b/dev-lang/python-exec/metadata.xml
new file mode 100644
index 0000000000..edb96f5bbb
--- /dev/null
+++ b/dev-lang/python-exec/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <upstream>
+    <maintainer status="active">
+      <email>mgorny@gentoo.org</email>
+      <name>Michał Górny</name>
+    </maintainer>
+    <bugs-to>https://github.com/mgorny/python-exec/issues/</bugs-to>
+    <remote-id type="bitbucket">mgorny/python-exec</remote-id>
+  </upstream>
+</pkgmetadata>
diff --git a/dev-lang/python-exec/python-exec-2.0.1-r1.ebuild b/dev-lang/python-exec/python-exec-2.0.1-r1.ebuild
new file mode 100644
index 0000000000..9f61668c91
--- /dev/null
+++ b/dev-lang/python-exec/python-exec-2.0.1-r1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+# Kids, don't do this at home!
+inherit python-utils-r1
+PYTHON_COMPAT=( "${_PYTHON_ALL_IMPLS[@]}" )
+
+inherit autotools-utils python-r1
+
+DESCRIPTION="Python script wrapper"
+HOMEPAGE="https://github.com/mgorny/python-exec/"
+SRC_URI="https://github.com/mgorny/${PN}/releases/download/${P}/${P}.tar.bz2"
+
+LICENSE="BSD-2"
+SLOT="2"
+KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+RDEPEND="!<dev-python/python-exec-10000"
+
+src_configure() {
+	local pyimpls i EPYTHON
+	for i in "${PYTHON_COMPAT[@]}"; do
+		python_export "${i}" EPYTHON
+		pyimpls+=" ${EPYTHON}"
+	done
+
+	local myeconfargs=(
+		--with-eprefix="${EPREFIX}"
+		--with-python-impls="${pyimpls}"
+	)
+
+	autotools-utils_src_configure
+}
diff --git a/dev-lang/python-exec/python-exec-2.0.2.ebuild b/dev-lang/python-exec/python-exec-2.0.2.ebuild
new file mode 100644
index 0000000000..80475b8560
--- /dev/null
+++ b/dev-lang/python-exec/python-exec-2.0.2.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+# Kids, don't do this at home!
+inherit python-utils-r1
+PYTHON_COMPAT=( "${_PYTHON_ALL_IMPLS[@]}" )
+
+inherit autotools-utils python-r1
+
+DESCRIPTION="Python script wrapper"
+HOMEPAGE="https://github.com/mgorny/python-exec/"
+SRC_URI="https://github.com/mgorny/${PN}/releases/download/${P}/${P}.tar.bz2"
+
+LICENSE="BSD-2"
+SLOT="2"
+KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh sparc x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+RDEPEND="!<dev-python/python-exec-10000"
+
+src_configure() {
+	local pyimpls i EPYTHON
+	for i in "${PYTHON_COMPAT[@]}"; do
+		python_export "${i}" EPYTHON
+		pyimpls+=" ${EPYTHON}"
+	done
+
+	local myeconfargs=(
+		--with-eprefix="${EPREFIX}"
+		--with-python-impls="${pyimpls}"
+	)
+
+	autotools-utils_src_configure
+}
diff --git a/dev-lang/python-exec/python-exec-2.1.ebuild b/dev-lang/python-exec/python-exec-2.1.ebuild
new file mode 100644
index 0000000000..4b4d2ac271
--- /dev/null
+++ b/dev-lang/python-exec/python-exec-2.1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+# Kids, don't do this at home!
+inherit python-utils-r1
+PYTHON_COMPAT=( "${_PYTHON_ALL_IMPLS[@]}" )
+
+# Inherited purely to have PYTHON_TARGET flags which will satisfy USE
+# dependencies and trigger necessary rebuilds.
+inherit python-r1
+
+DESCRIPTION="Python script wrapper"
+HOMEPAGE="https://github.com/mgorny/python-exec/"
+SRC_URI="https://github.com/mgorny/${PN}/releases/download/${P}/${P}.tar.bz2"
+
+LICENSE="BSD-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+RDEPEND="!<dev-python/python-exec-10000
+	!<app-eselect/eselect-python-20151117"
+
+src_configure() {
+	local pyimpls=() i EPYTHON
+	for i in "${PYTHON_COMPAT[@]}"; do
+		python_export "${i}" EPYTHON
+		pyimpls+=( "${EPYTHON}" )
+	done
+
+	local myconf=(
+		--with-eprefix="${EPREFIX}"
+		--with-python-impls="${pyimpls[*]}"
+	)
+
+	econf "${myconf[@]}"
+}
diff --git a/dev-lang/python-exec/python-exec-2.4.3.ebuild b/dev-lang/python-exec/python-exec-2.4.3.ebuild
new file mode 100644
index 0000000000..1db43aaa11
--- /dev/null
+++ b/dev-lang/python-exec/python-exec-2.4.3.ebuild
@@ -0,0 +1,134 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+# Kids, don't do this at home!
+inherit python-utils-r1
+PYTHON_COMPAT=( "${_PYTHON_ALL_IMPLS[@]}" )
+
+# Inherited purely to have PYTHON_TARGET flags which will satisfy USE
+# dependencies and trigger necessary rebuilds.
+inherit python-r1
+
+DESCRIPTION="Python script wrapper"
+HOMEPAGE="https://github.com/mgorny/python-exec/"
+SRC_URI="https://github.com/mgorny/${PN}/releases/download/${P}/${P}.tar.bz2"
+
+LICENSE="BSD-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+# eselect-python because of /usr/bin/python* collisions and new config
+# python versions because of missing $scriptdir/python* symlinks
+RDEPEND="
+	!<app-eselect/eselect-python-20160206
+	!<dev-lang/python-2.7.10-r4:2.7
+	!<dev-lang/python-3.3.5-r4:3.3
+	!<dev-lang/python-3.4.3-r4:3.4
+	!<dev-lang/python-3.5.0-r3:3.5"
+
+src_configure() {
+	local pyimpls=() i EPYTHON
+	for i in "${PYTHON_COMPAT[@]}"; do
+		python_export "${i}" EPYTHON
+		pyimpls+=( "${EPYTHON}" )
+	done
+
+	local myconf=(
+		--with-python-impls="${pyimpls[*]}"
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	# Prepare and own the template
+	sed -n -e '/^#/p' config/python-exec.conf.example \
+		> "${T}"/python-exec.conf || die
+	insinto /etc/python-exec
+	doins "${T}"/python-exec.conf
+
+	local f
+	for f in python{,2,3}; do
+		# symlink the C wrapper for python to avoid shebang recursion
+		# bug #568974
+		dosym python-exec2c /usr/bin/"${f}"
+	done
+	for f in python{,2,3}-config 2to3 idle pydoc pyvenv; do
+		# those are python scripts (except for new python-configs)
+		# so symlink them via the python wrapper
+		dosym ../lib/python-exec/python-exec2 /usr/bin/"${f}"
+	done
+}
+
+pkg_preinst() {
+	if [[ -e ${EROOT}etc/python-exec/python-exec.conf ]]; then
+		# preserve current configuration
+		cp "${EROOT}"etc/python-exec/python-exec.conf \
+			"${ED}"etc/python-exec/python-exec.conf || die
+	else
+		# preserve previous Python version preference
+		local py old_pythons=()
+		local config_base=${EROOT}etc/env.d/python
+
+		# start with the 'global' preference (2 vs 3)
+		if [[ -f ${config_base}/config ]]; then
+			old_pythons+=( "$(<${config_base}/config)" )
+		fi
+
+		# then try specific py3 selection
+		for py in 3; do
+			local target=
+
+			if [[ -f ${config_base}/python${py} ]]; then
+				# try the newer config files
+				target=$(<${config_base}/python${py})
+			elif [[ -L ${EROOT}/usr/bin/python${py} ]]; then
+				# check the older symlink format
+				target=$(readlink "${EROOT}/usr/bin/python${py}")
+
+				# check if it's actually old eselect symlink
+				[[ ${target} == python?.? ]] || target=
+			fi
+
+			# add the extra target if found and != global
+			if [[ ${target} && ${old_pythons[0]} != ${target} ]]; then
+				old_pythons+=( "${target}" )
+			fi
+		done
+
+		if [[ ${old_pythons[@]} ]]; then
+			elog "You seem to have just upgraded into the new version of python-exec"
+			elog "that uses python-exec.conf for configuration. The ebuild has attempted"
+			elog "to convert your previous configuration to the new format, resulting"
+			elog "in the following preferences (most preferred version first):"
+			elog
+			for py in "${old_pythons[@]}"; do
+				elog "  ${py}"
+			done
+			elog
+			elog "Those interpreters will be preferred when running Python scripts or"
+			elog "calling wrapped Python executables (python, python2, pydoc...)."
+			elog "If none of the preferred interpreters are supported, python-exec will"
+			elog "fall back to the newest supported Python version."
+			elog
+			elog "Please note that due to the ambiguous character of the old settings,"
+			elog "you may want to modify the preference list yourself. In order to do so,"
+			elog "open the following file in your favorite editor:"
+			elog
+			elog "  ${EROOT}etc/python-exec/python-exec.conf"
+			elog
+			elog "For more information on the new configuration format, please read"
+			elog "the comment on top of the installed configuration file."
+
+			local IFS=$'\n'
+			echo "${old_pythons[*]}" \
+				>> "${ED}"etc/python-exec/python-exec.conf || die
+		fi
+	fi
+}
diff --git a/dev-lang/python-exec/python-exec-9999.ebuild b/dev-lang/python-exec/python-exec-9999.ebuild
new file mode 100644
index 0000000000..c130a90f54
--- /dev/null
+++ b/dev-lang/python-exec/python-exec-9999.ebuild
@@ -0,0 +1,149 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+#if LIVE
+EGIT_REPO_URI="https://github.com/mgorny/${PN}.git"
+
+inherit autotools git-r3
+#endif
+
+# Kids, don't do this at home!
+inherit python-utils-r1
+PYTHON_COMPAT=( "${_PYTHON_ALL_IMPLS[@]}" )
+
+# Inherited purely to have PYTHON_TARGET flags which will satisfy USE
+# dependencies and trigger necessary rebuilds.
+inherit python-r1
+
+DESCRIPTION="Python script wrapper"
+HOMEPAGE="https://github.com/mgorny/python-exec/"
+SRC_URI="https://github.com/mgorny/${PN}/releases/download/${P}/${P}.tar.bz2"
+
+LICENSE="BSD-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+# eselect-python because of /usr/bin/python* collisions and new config
+# python versions because of missing $scriptdir/python* symlinks
+RDEPEND="
+	!<app-eselect/eselect-python-20160206
+	!<dev-lang/python-2.7.10-r4:2.7
+	!<dev-lang/python-3.3.5-r4:3.3
+	!<dev-lang/python-3.4.3-r4:3.4
+	!<dev-lang/python-3.5.0-r3:3.5"
+
+#if LIVE
+KEYWORDS=
+SRC_URI=
+
+src_prepare() {
+	eautoreconf
+}
+#endif
+
+src_configure() {
+	local pyimpls=() i EPYTHON
+	for i in "${PYTHON_COMPAT[@]}"; do
+		python_export "${i}" EPYTHON
+		pyimpls+=( "${EPYTHON}" )
+	done
+
+	local myconf=(
+		--with-python-impls="${pyimpls[*]}"
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	# Prepare and own the template
+	sed -n -e '/^#/p' config/python-exec.conf.example \
+		> "${T}"/python-exec.conf || die
+	insinto /etc/python-exec
+	doins "${T}"/python-exec.conf
+
+	local f
+	for f in python{,2,3}; do
+		# symlink the C wrapper for python to avoid shebang recursion
+		# bug #568974
+		dosym python-exec2c /usr/bin/"${f}"
+	done
+	for f in python{,2,3}-config 2to3 idle pydoc pyvenv; do
+		# those are python scripts (except for new python-configs)
+		# so symlink them via the python wrapper
+		dosym ../lib/python-exec/python-exec2 /usr/bin/"${f}"
+	done
+}
+
+pkg_preinst() {
+	if [[ -e ${EROOT}etc/python-exec/python-exec.conf ]]; then
+		# preserve current configuration
+		cp "${EROOT}"etc/python-exec/python-exec.conf \
+			"${ED}"etc/python-exec/python-exec.conf || die
+	else
+		# preserve previous Python version preference
+		local py old_pythons=()
+		local config_base=${EROOT}etc/env.d/python
+
+		# start with the 'global' preference (2 vs 3)
+		if [[ -f ${config_base}/config ]]; then
+			old_pythons+=( "$(<${config_base}/config)" )
+		fi
+
+		# then try specific py3 selection
+		for py in 3; do
+			local target=
+
+			if [[ -f ${config_base}/python${py} ]]; then
+				# try the newer config files
+				target=$(<${config_base}/python${py})
+			elif [[ -L ${EROOT}/usr/bin/python${py} ]]; then
+				# check the older symlink format
+				target=$(readlink "${EROOT}/usr/bin/python${py}")
+
+				# check if it's actually old eselect symlink
+				[[ ${target} == python?.? ]] || target=
+			fi
+
+			# add the extra target if found and != global
+			if [[ ${target} && ${old_pythons[0]} != ${target} ]]; then
+				old_pythons+=( "${target}" )
+			fi
+		done
+
+		if [[ ${old_pythons[@]} ]]; then
+			elog "You seem to have just upgraded into the new version of python-exec"
+			elog "that uses python-exec.conf for configuration. The ebuild has attempted"
+			elog "to convert your previous configuration to the new format, resulting"
+			elog "in the following preferences (most preferred version first):"
+			elog
+			for py in "${old_pythons[@]}"; do
+				elog "  ${py}"
+			done
+			elog
+			elog "Those interpreters will be preferred when running Python scripts or"
+			elog "calling wrapped Python executables (python, python2, pydoc...)."
+			elog "If none of the preferred interpreters are supported, python-exec will"
+			elog "fall back to the newest supported Python version."
+			elog
+			elog "Please note that due to the ambiguous character of the old settings,"
+			elog "you may want to modify the preference list yourself. In order to do so,"
+			elog "open the following file in your favorite editor:"
+			elog
+			elog "  ${EROOT}etc/python-exec/python-exec.conf"
+			elog
+			elog "For more information on the new configuration format, please read"
+			elog "the comment on top of the installed configuration file."
+
+			local IFS=$'\n'
+			echo "${old_pythons[*]}" \
+				>> "${ED}"etc/python-exec/python-exec.conf || die
+		fi
+	fi
+}