blob: ee450216bff01a6c308ec52855b45405f16c2149 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit desktop xdg
DESCRIPTION="Manager for the Ledger hardware wallet"
HOMEPAGE="https://www.ledger.com/"
SRC_URI="https://download.live.ledger.com/ledger-live-desktop-${PV}-linux-x86_64.AppImage"
S="${WORKDIR}/squashfs-root"
# logos of Ledger are non-free
LICENSE="ledger-live-ToU MIT"
SLOT="0"
KEYWORDS="~amd64"
RESTRICT="strip"
RDEPEND="
app-accessibility/at-spi2-core:2
dev-libs/expat
dev-libs/glib:2
dev-libs/nspr
dev-libs/nss
media-libs/alsa-lib
media-libs/mesa
net-print/cups
sys-apps/dbus
x11-libs/cairo
x11-libs/gtk+:3
x11-libs/libX11
x11-libs/libXcomposite
x11-libs/libXdamage
x11-libs/libXext
x11-libs/libXfixes
x11-libs/libXrandr
x11-libs/libdrm
x11-libs/libxcb
x11-libs/libxkbcommon
x11-libs/pango
"
QA_PREBUILT="*"
src_unpack() {
cp "${DISTDIR}"/ledger-live-desktop-${PV}-linux-x86_64.AppImage ${P}.AppImage || die
chmod +x ${P}.AppImage || die
./${P}.AppImage --appimage-extract || die
rm ${P}.AppImage || die
}
src_prepare() {
default
sed -e 's/AppRun --no-sandbox/ledger-live/' \
-e '/X-AppImage-Version/d' \
-i ledger-live-desktop.desktop || die
}
src_install() {
exeinto /opt/${PN}
doexe chrome{-sandbox,_crashpad_handler} ledger-live-desktop
insinto /opt/${PN}
doins -r *.{bin,dat,json,pak} locales resources lib*
fperms u+s /opt/${PN}/chrome-sandbox
domenu ledger-live-desktop.desktop
insinto /usr/share
doins -r usr/share/icons
dosym -r /opt/${PN}/ledger-live-desktop /usr/bin/ledger-live
# bug 937379
rm "${ED}"/opt/${PN}/resources/app-update.yml || die
find "${ED}" -type d -exec chmod 755 {} + || die
}
|
GitWeb
