app-text/komikku: add 1.47.0

Signed-off-by: Takuya Wakazono <pastalian46@gmail.com>

2 files changed, 95 insertions, 0 deletions

diff --git a/app-text/komikku/Manifest b/app-text/komikku/Manifest
index 40e02d7cf..5a1c2840f 100644
--- a/app-text/komikku/Manifest
+++ b/app-text/komikku/Manifest
@@ -1 +1,2 @@
 DIST komikku-1.39.0.tar.gz 3704061 BLAKE2B a5d42be1de44db10adad1086172d8760a9cb313f7dc7b5654ccef3a50fceea4d8f9abcb98f8be40c393ec1a2a4a655cbb164d34b69e6142069b526ce40cf345d SHA512 c8c8c2d6cb4beadb7eba22d6764bd49c469614ae49c345723a22cf68376262516d733495f1530206fce20333c408062c50fd88533ef841ff8cbaef7ab06e121a
+DIST komikku-1.47.0.tar.gz 4893601 BLAKE2B 0154378c90650d9ac6e2931ec0703016eac73d686a3a5367959e55dd88abecdfc2a8ab060850585027b0fe45f4a6fd16b83b25b923214c90b5aad01f13e0a90a SHA512 1c8af6d4e2f90c953149fc82580562042c1d33025a85cae951af5e5ad37abd62d1a5a7de934033820a22a124c261d2b87b3053a6893c2e4e0b5ad9c42f18b01c
diff --git a/app-text/komikku/komikku-1.47.0.ebuild b/app-text/komikku/komikku-1.47.0.ebuild
new file mode 100644
index 000000000..432b5e944
--- /dev/null
+++ b/app-text/komikku/komikku-1.47.0.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="sqlite(+),ssl(+)"
+DISTUTILS_USE_PEP517=no
+DISTUTILS_SINGLE_IMPL=1
+inherit distutils-r1 meson gnome2-utils xdg
+
+DESCRIPTION="Manga reader for GNOME"
+HOMEPAGE="https://apps.gnome.org/Komikku/"
+SRC_URI="https://codeberg.org/valos/Komikku/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RESTRICT="test"
+# Depend on a random server that may or may not be accessible at all times.
+PROPERTIES="test_network"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	>=gui-libs/gtk-4.12:4
+	>=gui-libs/libadwaita-1.5:1[introspection]
+	net-libs/webkit-gtk:6[introspection]
+"
+RDEPEND="
+	${DEPEND}
+	x11-libs/libnotify[introspection]
+	$(python_gen_cond_dep '
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/colorthief[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/dateparser[${PYTHON_USEDEP}]
+		dev-python/emoji[${PYTHON_USEDEP}]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-python/piexif[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pillow-heif[${PYTHON_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		dev-python/rarfile[compressed,${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/unidecode[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	dev-util/blueprint-compiler
+	sys-devel/gettext
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pytest-steps[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# fix broken shebang
+	sed "s|py_installation.full_path()|'${PYTHON}'|" -i bin/meson.build || die
+}
+
+src_test() {
+	emake setup
+	emake develop
+	emake test
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}